# class Backtrace

Snapshot of the dynamic call stack

```
class Backtrace is List { ... }
```

A backtrace shows the dynamic call stack, usually leading up to a point where an exception was thrown.

It is a List of Backtrace::Frame objects. Its default stringification excludes backtrace frames that are deemed unnecessary or confusing, for example routines like `&die`

are hidden by default.

# Methods

## method new

Defined as:

```
proto method new(*@, *%) {*}
multi method new()
```

Usage:

```
$backtrace = Backtrace.new
```

Creates a new backtrace, using its calling location as the origin of the backtrace.

## method Str

Defined as:

```
multi method Str(Backtrace:D:) returns Str:D:
```

Usage:

```
BACKTRACE.Str
```

Returns a concise string representation of the backtrace, omitting routines marked as `is hidden-from-backtrace`

, and at the discretion of the implementor, also some routines from the setting.

## method full

Defined as:

```
multi method full(Backtrace:D:) returns Str:D:
```

Usage:

```
BACKTRACE.full
```

Returns a full string representation of the backtrace, including hidden frames, compiler-specific frames and those from the setting.

# Type graph

# Routines supplied by class List

Backtrace inherits from class List, which provides the following methods:

## routine elems

Defined as:

```
multi sub elems($list) returns Int:D
multi method elems(List:D:) returns Int:D
```

Usage:

```
elems LIST
LIST.elems
```

Returns the number of elements in the list.

## routine end

Defined as:

```
multi sub end($list) returns Int:D
multi method end(List:D:) returns Int:D
```

Usage:

```
end LIST
LIST.end
```

Returns the index of the last element.

## routine keys

Defined as:

```
multi sub keys($list) returns Seq:D
multi method keys(List:D:) returns Seq:D
```

Usage:

```
keys LIST
LIST.keys
```

Returns a sequence of indexes into the list (e.g., 0..(@list.elems-1)).

## routine values

Defined as:

```
multi sub values($list) returns Seq:D
multi method values(List:D:) returns Seq:D
```

Usage:

```
values LIST
LIST.values
```

Returns a sequence of the list elements, in order.

## routine kv

Defined as:

```
multi sub kv($list) returns Seq:D
multi method kv(List:D:) returns Seq:D
```

Usage:

```
kv LIST
LIST.kv
```

Returns an interleaved sequence of indexes and values. For example

```
<a b c>.kv
```

Returns

```
(0, 'a', 1, 'b', 2, 'c').Seq
```

## routine pairs

Defined as:

```
multi sub pairs($list) returns Seq:D
multi method pairs(List:D:) returns Seq:D
```

Usage:

```
pairs LIST
LIST.pairs
```

Returns a sequence of pairs, with the indexes as keys and the list values as values.

```
<a b c>.pairs # (0 => 'a', 1 => 'b', 2 => 'c').Seq
```

## routine join

Defined as:

```
multi sub join($separator, *@list) returns Str:D
multi method join(List:D: $separator) returns Str:D
```

Usage:

```
join SEPARATOR, LIST
LIST.join(SEPARATOR)
```

Treats the elements of the list as strings, interleaves them with `$separator`

and concatenates everything into a single string.

Example:

```
join ', ', <a b c>; # a, b, c
```

Note that the method form does not flatten sublists:

```
say (1, <a b c>).join('|'); # 1|a b c
```

## routine map

Defined as:

```
multi sub map(&code, *@elems) returns Seq:D
multi method map(List:D: &code) returns Seq:D
```

Usage:

```
map CODE, LIST
LIST.map(CODE)
```

Invokes `&code`

for each element and gathers the return values in a sequence and returns it. This happens lazily, i.e. `&code`

is only invoked when the return values are accessed.

Examples:

```
> ('hello', 1, 22/7, 42, 'world').map: { .WHAT.perl }
(Str Int Rat Int Str)
> map *.Str.chars, 'hello', 1, 22/7, 42, 'world'
(5 1 8 2 5)
```

`map`

inspects the arity of the code object, and tries to pass as many arguments to it as expected:

```
sub b($a, $b) { "$a before $b" };
say <a b x y>.map(&b).join(', '); # a before b, x before y
```

iterates the list two items at a time.

Note that `map`

does not flatten embedded lists and arrays, so

```
((1, 2), <a b>).map({ .join(',')})
```

passes `(1, 2)`

and `<a b> `

in turn to the block, leading to a total of two iterations and the result sequence `"1,2", "a,b"`

. See method flatmap for an alternative that flattens.

## sub flat

Defined as:

```
sub flat(**@list is raw)
```

Constructs a list which contains any arguments provided in the order provided, and returns the result of calling the `.flat`

method (inherited from `Any`

) on that list:

```
flat 1, (2, (3, 4), $(5, 6))); # (1, 2, 3, 4, $(5, 6)).Seq
```

## method flatmap

Defined as:

```
method flatmap(List:D: &code) returns Seq:D
```

Usage:

```
LIST.flatmap(CODE)
```

Like `map`

iterates over the elements of the invocant list, feeding each element in turn to the code reference, and assembling the return values from these invocations in a result list.

Unlike `map`

it flattens non-itemized lists and arrays, so

```
say ((1, 2), <a b>).flatmap(&uc).join('|'); # 1|2|A|B
```

invokes uc four times.

## routine grep

Defined as:

```
multi sub grep(Mu $matcher, *@elems, :k, :kv, :p, :v) returns Seq:D
multi method grep(List:D: Mu $matcher, :k, :kv, :p, :v) returns Seq:D
```

Usage:

```
grep MATCHER, LIST
grep MATCHER, LIST, :RETURN_AS
LIST.grep(MATCHER)
LIST.grep(MATCHER, :RETURN_AS)
```

Returns a sequence of elements against which `$matcher`

smart-matches. The elements are returned in the order in which they appear in the original list.

Examples:

```
> ('hello', 1, 22/7, 42, 'world').grep: Int
(1 42)
> grep { .Str.chars > 3 }, 'hello', 1, 22/7, 42, 'world'
(hello 3.142857 world)
```

The optional named parameters `:k`

, `:kv`

, `:p`

, `:v`

provide the same functionality as on slices:

k

Only return the index values of the matching elements in order.

kv

Return both the index and matched elements in order.

p

Return the index and the matched element as a `Pair`

, in order.

v

Only return the matched elements (same as not specifying any named parameter at all).

Examples:

```
> ('hello', 1, 22/7, 42, 'world').grep: Int, :k
(1 3)
> grep { .Str.chars > 3 }, :kv, 'hello', 1, 22/7, 42, 'world'
(0 hello 2 3.142857 4 world)
> grep { .Str.chars > 3 }, :p, 'hello', 1, 22/7, 42, 'world'
(0 => hello 2 => 3.142857 4 => world)
```

## routine first

Defined as:

```
multi sub first(Mu $matcher, *@elems, :k, :kv, :p, :end)
multi method first(List:D: Mu $matcher, :k, :kv, :p, :end)
```

Usage:

```
first MATCHER, LIST, :RETURN_AS, :FROM_END
LIST.first(MATCHER, :RETURN_AS, :FROM_END)
```

Returns the first item of the list which smart-matches against `$matcher`

, returns Nil when no values match. The optional named parameter `:end`

indicates that the search should be from the **end** of the list, rather than from the start.

Examples:

```
say (1, 22/7, 42, 300).first: * > 5; # 42
say (1, 22/7, 42, 300).first: * > 5, :end; # 300
say ('hello', 1, 22/7, 42, 'world').first: Complex; # Nil
```

The optional named parameters `:k`

, `:kv`

, `:p`

provide the same functionality as on slices:

k

Return the index value of the matching element. Index is always counted from the beginning of the list, regardless of whether the `:end`

named parameter is specified or not.

kv

Return both the index and matched element.

p

Return the index and the matched element as a `Pair`

.

Examples:

```
say (1, 22/7, 42, 300).first: * > 5, :k; # 2
say (1, 22/7, 42, 300).first: * > 5, :p; # 2 => 42
say (1, 22/7, 42, 300).first: * > 5, :kv, :end; # 3 300
```

## method head

Defined as:

```
multi method head(List:D: Int(Cool) $number = 1) returns Seq:D
```

Usage:

```
LIST.head
LIST.head(NUMBER)
```

Returns the **first** NUMBER items of the list. Returns an empty list if NUMBER <= 0. Defaults to the first element seen if no NUMBER specified.

Examples:

```
say ^10 .head(5) # 0 1 2 3 4
say ^Inf .head(5) # 0 1 2 3 4
say ^10 .head # 0
say ^Inf .head # 0
```

## method tail

Defined as:

```
multi method tail(List:D: Int(Cool) $number = 1) returns Seq:D
```

Usage:

```
LIST.tail
LIST.tail(NUMBER)
```

Returns a Seq containing the **last** NUMBER items of the list. Returns an empty Seq if NUMBER <= 0. Defaults to the last element if no NUMBER is specified. Throws an exception if the list is lazy.

Examples:

```
say ^10 .tail(5) # 5 6 7 8 9
say ^Inf .tail(5) # Cannot tail a lazy list
say ^10 .tail # 9
say ^Inf .tail # Cannot tail a lazy list
```

## routine categorize

Defined as:

```
multi sub categorize(&mapper, *@values) returns Hash:D
multi method categorize(List:D: &mapper) returns Hash:D
```

Usage:

```
categorize MAPPER, LIST
LIST.categorize(MAPPER)
```

Transforms a list of values into a hash representing the categorizations of those values according to a mapper; each hash key represents one possible categorization for one or more of the incoming list values, and the corresponding hash value contains an array of those list values categorized by the mapper into the category of the associated key.

Note that, unlike classify, which assumes that the return value of the mapper is a single value, `categorize`

always assumes that the return value of the mapper is a list of categories that are appropriate to the current value.

Example:

```
sub mapper(Int $i) returns List {
$i %% 2 ?? 'even' !! 'odd',
$i.is-prime ?? 'prime' !! 'not prime'
}
say categorize &mapper, (1, 7, 6, 3, 2); # {even => [6 2], not prime => [1 6],
# odd => [1 7 3], prime => [7 3 2]}
```

## routine classify

Defined as:

```
multi sub classify(&mapper, *@values) returns Hash:D
multi method classify(List:D: &mapper) returns Hash:D
```

Usage:

```
classify MAPPER, LIST
LIST.classify(MAPPER)
```

Transforms a list of values into a hash representing the classification of those values according to a mapper; each hash key represents the classification for one or more of the incoming list values, and the corresponding hash value contains an array of those list values classified by the mapper into the category of the associated key.

Example:

```
say classify { $_ %% 2 ?? 'even' !! 'odd' }, (1, 7, 6, 3, 2);
#-> even => 6 2, odd => 1 7 3
say ('hello', 1, 22/7, 42, 'world').classify: { .Str.chars };
#-> 1 => 1, 2 => 42, 5 => hello world, 8 => 3.142857
```

## method Bool

Defined as:

```
multi method Bool(List:D:) returns Bool:D
```

Usage:

```
LIST.Bool
```

Returns `True`

if the list has at least one element, and `False`

for the empty list.

## method Str

Defined as:

```
multi method Str(List:D:) returns Str:D
```

Usage:

```
LIST.Str
```

Stringifies the elements of the list and joins them with spaces (same as `.join(' ')`

).

## method Int

Defined as:

```
multi method Int(List:D:) return Int:D
```

Usage:

```
LIST.Int
```

Returns the number of elements in the list (same as `.elems`

).

## method Numeric

Defined as:

```
multi method Numeric(List:D:) return Int:D
```

Usage:

```
LIST.Numeric
```

Returns the number of elements in the list (same as `.elems`

).

## method Capture

Defined as:

```
method Capture() returns Capture:D
```

Usage:

```
LIST.Capture
```

Returns a Capture where each Pair, if any, in the `List`

has been converted to a named argument. All other elements in the `List`

are converted to positional arguments in the order they are found, i.e. the first non pair item in the list becomes the first positional argument, which gets index `0`

, the second non pair item becomes the second positional argument, getting index `1`

etc.

```
my $list = (7, 5, a => 2, b => 17);
my $capture = $list.Capture;
say $capture.keys; # (0 1 a b)
my-sub(|$capture); # 7, 5, 2, 17
sub my-sub($first, $second, :$a, :$b) {
say "$first, $second, $a, $b"
}
```

A more advanced example demonstrating the returned `Capture`

being matched against a Signature.

```
my $list = (7, 5, a => 2, b => 17);
say so $list.Capture ~~ :($ where * == 7,$,:$a,:$b); # True
$list = (8, 5, a => 2, b => 17);
say so $list.Capture ~~ :($ where * == 7,$,:$a,:$b); # False
```

## routine pick

Defined as:

```
multi sub pick($count, *@list) returns Seq:D
multi method pick(List:D: $count = 1) returns Mu
```

Usage:

```
pick COUNT, LIST
LIST.pick(COUNT)
```

Returns `$count`

elements chosen at random and without repetition from the invocant. If `*`

is passed as `$count`

, or `$count`

is greater than or equal to the size of the list, then all elements from the invocant list are returned in a random sequence.

Examples:

```
say <a b c d e>.pick; # b
say <a b c d e>.pick: 3; # (c a e)
say <a b c d e>.pick: *; # (e d a b c)
```

## routine roll

Defined as:

```
multi sub roll($count, *@list) returns Seq:D
multi method roll(List:D: $count = 1)
```

Usage:

```
roll COUNT, LIST
LIST.roll(COUNT)
```

Returns a sequence of `$count`

elements, each randomly selected from the list. Each random choice is made independently, like a separate die roll where each die face is a list element.

If `*`

is passed to `$count`

, returns a lazy, infinite sequence of randomly chosen elements from the original list.

Examples:

```
say <a b c d e>.roll; # b
say <a b c d e>.roll: 3; # c c e
say roll 8, <a b c d e>; # b a e d a e b c
my $random_digits := (^10).roll(*);
say $random_digits[^15]; # 3 8 7 6 0 1 3 2 0 8 8 5 8 0 5
```

## routine eager

Defined as:

```
multi method eager(List:D:) returns List:D
sub eager(*@elems) returns List:D
```

Usage:

```
eager LIST
LIST.eager
```

Evaluates all elements in the list eagerly, and returns them as a list.

## routine reverse

Defined as:

```
multi sub reverse(*@list ) returns List:D
multi method reverse(List:D:) returns List:D
```

Usage:

```
reverse(LIST)
LIST.reverse
```

Returns a list with the same elements in reverse order.

Note that `reverse`

always refers to reversing elements of a list; to reverse the characters in a string, use flip.

Examples:

```
say <hello world!>.reverse # world! hello
say reverse ^10 # 9 8 7 6 5 4 3 2 1 0
```

## routine rotate

Defined as:

```
multi sub rotate(@list, Int:D $n = 1) returns List:D
multi method rotate(List:D: Int:D $n = 1) returns List:D
```

Usage:

```
rotate(LIST, INTEGER?)
LIST.rotate(INTEGER?)
```

Returns the list rotated by `$n`

elements.

Examples:

```
<a b c d e>.rotate(2); # <c d e a b>
<a b c d e>.rotate(-1); # <e a b c d>
```

## routine sort

Defined as:

```
multi sub sort(*@elems) returns Seq:D
multi sub sort(&by, *@elems) returns Seq:D
multi method sort(List:D:) returns Seq:D
multi method sort(List:D:, &by) returns Seq:D
```

Usage:

```
sort LIST
sort SORT_BY, LIST
LIST.sort
LIST.sort(SORT_BY)
```

Sorts the list, smallest element first. By default `infix:<cmp> `

is used for comparing list elements.

If `&by`

is provided, and it accepts two arguments, it is invoked for pairs of list elements, and should return `Order::Increase`

, `Order::Same`

or `Order::Decrease`

.

If `&by`

accepts only one argument, the list elements are sorted according to `by($a) cmp by($b) `

. The return values of `&by`

are cached, so that `&by`

is only called once per list element.

Examples:

```
say (3, -4, 7, -1, 2, 0).sort; # -4 -1 0 2 3 7
say (3, -4, 7, -1, 2, 0).sort: *.abs; # 0 -1 2 3 -4 7
say (3, -4, 7, -1, 2, 0).sort: { $^b leg $^a }; # 7 3 2 0 -4 -1
```

## routine unique

Defined as:

```
multi sub unique(*@values, :&as, :&with) returns Seq:D
multi method unique(List:D:, :&as, :&with) returns Seq:D
```

Usage:

```
unique LIST, :COMPARE_AS, :COMPARE_WITH
LIST.unique(:COMPARE_AS, :COMPARE_WITH)
```

Returns a sequence of **unique** values from the invocant/argument list, such that only the first occurrence of each duplicated value remains in the result list. `unique`

uses the semantics of the === operator to decide whether two objects are the same, unless the optional `:with`

parameter is specified with another comparator. The order of the original list is preserved even as duplicates are removed.

Examples:

```
say <a a b b b c c>.unique # a b c
say <a b b c c b a>.unique # a b c
```

(Use `squish`

instead if you know the input is sorted such that identical objects are adjacent.)

The optional `:as`

parameter allows you to normalize/canonicalize the elements before unique-ing. The values are transformed for the purposes of comparison, but it's still the original values that make it to the result list:

Example:

```
say <a A B b c b C>.unique(:as(&lc)) # a B c
```

One can also specify the comparator with the optional `:with`

parameter. For instance if one wants a list of unique hashes, one could use the `eqv`

comparator.

Example:

```
my @list = {a => 42}, {b => 13}, {a => 42};
say @list.unique(:with(&[eqv])) # {a=>42} {b=>13}
```

## routine repeated

Defined as:

```
multi sub repeated(*@values, :&as, :&with) returns Seq:D
multi method repeated(List:D:, :&as, :&with) returns Seq:D
```

Usage:

```
repeated LIST, :COMPARE_AS, :COMPARE_WITH
LIST.repeated(:COMPARE_AS, :COMPARE_WITH)
```

Returns a sequence of **repeated** values from the invocant/argument list. It takes the same parameters as `unique`

, but instead of passing through any elements when they're first seen, they're only passed through as soon as they're seen for the second time (or more).

Examples:

```
say <a a b b b c c>.repeated # a b b c
say <a b b c c b a>.repeated # b c b a
say <a A B b c b C>.repeated(:as(&lc)) # A b b C
my @list = {a => 42}, {b => 13}, {a => 42};
say @list.repeated(:with(&[eqv])) # {a=>42}
```

## routine squish

Defined as:

```
multi sub squish(*@values, :&as) returns Seq:D
multi method squish(List:D:, :&as) returns Seq:D
```

Usage:

```
squish LIST, :COMPARE_AS
LIST.squish(:COMPARE_AS)
```

Returns a sequence of values from the invocant/argument list where runs of more than one value are replaced with only the first instance. Like `unique`

, `squish`

uses the semantics of the === operator to decide whether two objects are the same. Unlike `unique`

, this function only removes adjacent duplicates; identical values further apart are still kept. The order of the original list is preserved even as duplicates are removed.

Examples:

```
say <a a b b b c c>.squish # a b c
say <a b b c c b a>.squish # a b c b a
```

The optional `:as`

parameter, just like with `unique`

, allows values to be temporarily transformed before comparison.

## routine reduce

Defined as:

```
multi sub reduce(&with, *@values)
multi method reduce(List:D: &with)
```

Usage:

```
reduce CODE, LIST
LIST.reduce(CODE)
```

Generates a single "combined" value from a list of arbitrarily many of values, by repeatedly applying a function which knows how to combine *two* values.

More precisely, the specified `&with`

is first called for the first two values of the list, then for the result of that calculation and the third value, and so on - and the final result is returned. In other words, `(2, 4, 6, 8).reduce(*+*)`

is the same as `(((2+4)+6)+8)`

.

If `@values`

contains just a single element, that element is returned immediately. If it contains no elements, an exception is thrown. For this reason, you may want to prefix the input list with an explicit identity value:

```
say reduce { $^a ~ $^b }, '', |@strings; # like @strings.join
say reduce { $^a > $^b ?? $^a !! $^b }, 0, |@numbers; # like @numbers.max
```

As a special case, if `&with`

is the function object of an *operator*, its inherent identity value and associativity is respected - in other words, `(VAL1, VAL2, VAL3).reduce(&[OP])`

is the same as `VAL1 OP VAL2 OP VAL3`

even for operators which aren't left-associative, and an empty `@values`

list is allowed now. And since reducing with an infix operator is a common thing to do, the `[ ]`

meta-operator provides a syntactic shortcut:

```
# The following all do the same thing...
say reduce { $^a + $^b }, 0, |@numbers;
say reduce * + *, 0, |@numbers;
say reduce &[+], @numbers;
say [+] @numbers;
```

Since `reduce`

is an implicit loop, it responds to `next`

, `last`

and `redo`

statements.

Practical example:

```
# Generate a random-ish math formula like "(4 + ((3 * x) + 11) / 6))"
my @ops = [Z] (<+ - * />, 1..20)».roll(4);
say ('x', |@ops).reduce: -> $formula, [$op, $number] {
Bool.pick ?? "($formula $op $number)"
!! "($number $op $formula)"
}
```

*Note:* In the functional programming world, this operation is generally called a left fold.

## routine combinations

Defined as:

```
multi sub combinations($n, $k) returns Seq:D
multi method combinations(List:D: Int:D $of) returns Seq:D
multi method combinations(List:D: Range:D $of = 0..*) returns Seq:D
```

Usage:

```
combinations INTEGER, INTEGER
LIST.combinations(INTEGER)
LIST.combinations(RANGE)
```

The `Int`

variant returns all `$of`

-combinations of the invocant list. For example

```
say .join('|') for <a b c>.combinations(2);
```

prints

```
a|b
a|c
b|c
```

because all the 2-combinations of `'a', 'b', 'c'`

are `['a', 'b'], ['a', 'c'], ['b', 'c']`

.

The `Range`

variant combines all the individual combinations into a single list, so

```
say .join('|') for <a b c>.combinations(2..3);
```

prints

```
a|b
a|c
b|c
a|b|c
```

because that's the list of all 2- and 3-combinations.

The subroutine form `combinations($n, $k)`

is equivalent to `(^$n).combinations($k)`

, so

```
.say for combinations(4, 2)
```

prints

```
0 1
0 2
0 3
1 2
1 3
2 3
```

## routine permutations

Defined as:

```
multi sub permutations($n) returns Seq:D
multi method permutations(List:D:) returns Seq:D
```

Usage:

```
permutations(INTEGER)
LIST.permutations
```

Returns all possible permutations of a list as a sequence of lists. So

```
say .join('|') for <a b c>.permutations
```

prints

```
a|b|c
a|c|b
b|a|c
b|c|a
c|a|b
c|b|a
```

`permutations`

treats all list elements as distinguishable, so `(1, 1, 2).permutations`

still returns a list of 6 elements, even though there are only three distinct permutations.

The subroutine form `permutations($n)`

is equivalent to `(^$n).permutations`

, so

```
.say for permutations 3;
```

prints

```
0 1 2
0 2 1
1 0 2
1 2 0
2 0 1
2 1 0
```

## method rotor

Defined as:

```
method rotor(*@cycle, Bool() :$partial) returns Seq:D
```

Usage:

```
LIST.rotor(EXPR, :partial?)
```

Returns a sequence of lists, where each sublist is made up of elements of the invocant.

In the simplest case, `@cycle`

contains just one integer, in which case the invocant list is split into sublists with as many elements as the integer specifies. If `:$partial`

is True, the final chunk is included even if it doesn't satisfy the length requirement:

```
say ('a'..'h').rotor(3).join('|'); # a b c|d e f
say ('a'..'h').rotor(3, :partial).join('|'); # a b c|d e f|g h
```

If the element of `@cycle`

is a Pair instead, the key of the pair specifies the length of the return sublist, and the value the gap between sublists; negative gaps produce overlap:

```
say ('a'..'h').rotor(2 => 1).join('|'); # a b|d e|g h
say ('a'..'h').rotor(3 => -1).join('|'); # a b c|c d e|e f g
```

If `@cycle`

contains more than element, `rotor`

cycles through it to find the number of elements for each sublist:

```
say ('a'..'h').rotor(2, 3).join('|'); # a b|c d e|f g
say ('a'..'h').rotor(1 => 1, 3).join('|'); # a|c d e|f
```

Combining multiple cycles and `:partial`

also works:

```
say ('a'..'h').rotor(1 => 1, 3 => -1, :partial).join('|');
# a|c d e|e|g h
```

See this blog post for more elaboration on rotor.

## routine zip

Defined as:

```
sub zip(**@e) returns Seq:D
```

Usage:

```
zip LISTS
```

Zips two or more lists or other iterables together by returning a sequence made of a list of all first elements of all lists, then a list of all second elements of a list etc.

```
say .join for zip <a b c>, <d e f>;
```

Produces the output

```
ad
be
cf
```

`zip`

has an infix synonym, the `Z`

operator.

```
say .join for <a b c> Z <d e f>; # same output as above
```

When the first input list is exhausted, no more elements are returned; so trailing elements from longer input lists are discarded.

If you just wish to skip missing entries in shorter sublists, use roundrobin instead:

```
for roundrobin(@queue1, @queue2, @queue3) -> $next {
...
}
```

## sub roundrobin

Defined as:

```
multi roundrobin(List:D: --> Seq)
```

Usage:

```
roundrobin LISTS
```

`roundrobin`

is very similar to zip. The difference is that `roundrobin`

will not stop on lists that run out of elements but simply skip any undefined value:

```
my @a = 1;
my @b = 1..2;
my @c = 1..3;
for flat roundrobin(@a, @b, @c) -> $x { $x.say }
```

will display the following values: `1, 1, 1, 2, 2, 3`

## routine sum

Defined as:

```
multi sub sum($list) returns Numeric:D
multi method sum(List:D:) returns Numeric:D
```

Usage:

```
sum LIST
LIST.sum
```

Returns the sum of all elements in the list or 0 if the list is empty. Throws an exception if an element can not be coerced into Numeric.

```
say (1, 3, pi).sum; # 7.14159265358979
say (1, "0xff").sum; # 256
say sum(0b1111, 5); # 20
```

## method fmt

Defined as:

```
method fmt($format = '%s', $separator = ' ') returns Str:D
```

Returns a string where each element in the list has been formatted according to `$format`

and where each element is separated by `$separator`

.

For more information about formats strings, see sprintf.

```
my @a = 8..11;
say @a.fmt('%03d', ','); # 008,009,010,011
```

# Methods supplied by role Positional

Backtrace inherits from class List, which does role Positional, which provides the following methods:

## method of

```
method of()
```

Returns the type constraint for elements of the positional container. Defaults to Mu.

# Methods supplied by role Iterable

Backtrace inherits from class List, which does role Iterable, which provides the following methods:

## method iterator

Defined as:

```
method iterator() returns Iterator:D { ... }
```

Method stub that ensures all classes doing the `Iterable`

role have a method `iterator`

.

It is supposed to return an Iterator.

## method flat

Defined as:

```
method flat() return Iterable
```

Usage:

```
ITERABLE.flat
```

Returns another Iterable that flattens out all iterables that the first one returns.

For example

```
say (<a b>, 'c').elems; # 2
say (<a b>, 'c').flat.elems; # 3
```

because `<a b> `

is a List and thus iterable, so `(<a b>, 'c').flat `

returns `('a', 'b', 'c')`

, which has three elems.

Note that the flattening is recursive, so `((("a", "b"), "c"), "d").flat`

returns `("a", "b", "c", "d")`

, but it does not flatten itemized sublists:

```
say ($('a', 'b'), 'c').perl; # ($("a", "b"), "c").Seq
```

## method lazy

Defined as:

```
method lazy() returns Iterable
```

Usage:

```
ITERABLE.lazy
```

Returns a lazy iterable wrapping the invocant.

## method hyper

Defined as:

```
method hyper(Int(Cool) :$batch = 64, Int(Cool) :$degree = 4)
returns Iterable
```

Usage:

```
ITERABLE.hyper(BATCH?, DEGREE?)
```

Returns another Iterable that is potentially iterated in parallel, with a given batch size and degree of parallelism.

The order of elements is preserved.

## method race

Defined as:

```
method race(Int(Cool) :$batch = 64, Int(Cool) :$degree = 4)
returns Iterable
```

Usage:

```
ITERABLE.race(BATCH?, DEGREE?)
```

Returns another Iterable that is potentially iterated in parallel, with a given batch size and degree of parallelism (number of parallel workers).

Unlike `hyper`

, `race`

does not preserve the order of elements.

# Routines supplied by class Cool

Backtrace inherits from class Cool, which provides the following methods:

## routine abs

Defined as:

```
sub abs(Numeric() $x)
method abs()
```

Usage:

```
abs NUMERIC
NUMERIC.abs
```

Coerces the invocant (or in the sub form, the argument) to Numeric and returns the absolute value (that is, a non-negative number).

```
say (-2).abs; # 2
say abs "6+8i"; # 10
```

## method conj

Defined as:

```
method conj()
```

Usage:

```
NUMERIC.conj
```

Coerces the invocant to Numeric and returns the complex conjugate (that is, the number with the sign of the imaginary part negated).

```
say (1+2i).conj; # 1-2i
```

## routine sqrt

Defined as:

```
sub sqrt(Numeric(Cool) $x)
method sqrt()
```

Usage:

```
sqrt NUMERIC
NUMERIC.sqrt
```

Coerces the invocant to Numeric (or in the sub form, the argument) and returns the square root, that is, a non-negative number that, when multiplied with itself, produces the original number.

```
say 4.sqrt; # 2
say sqrt(2); # 1.4142135623731
```

## method sign

Defined as:

```
method sign()
```

Usage:

```
NUMERIC.sign
```

Coerces the invocant to Numeric and returns its sign, that is, 0 if the number is 0, 1 for positive and -1 for negative values.

```
say 6.sign; # 1
say (-6).sign; # -1
say "0".sign; # 0
```

## method rand

Defined as:

```
method rand()
```

Usage: NUMERIC.rand

Coerces the invocant to Num and returns a pseudo-random value between zero and the number.

```
say 1e5.rand; # 33128.495184283
```

## routine sin

Defined as:

```
sub sin(Numeric(Cool))
method sin()
```

Usage:

```
sin NUMERIC
NUMERIC.sin
```

Coerces the invocant (or in the sub form, the argument) to Numeric, interprets it as radians, returns its sine.

```
say sin(0); # 0
say sin(pi/4); # 0.707106781186547
say sin(pi/2); # 1
```

Note that Perl 6 is no computer algebra system, so `sin(pi)`

typically does not produce an exact 0, but rather a very small floating-point number.

## routine asin

Defined as:

```
sub asin(Numeric(Cool))
method asin()
```

Usage:

```
asin NUMERIC
NUMERIC.asin
```

Coerces the invocant (or in the sub form, the argument) to Numeric, and returns its arc-sine in radians.

```
say 0.1.asin; # 0.10016742116156
```

## routine cos

Defined as:

```
sub cos(Numeric(Cool))
method cos()
```

Usage:

```
cos NUMERIC
NUMERIC.cos
```

Coerces the invocant (or in sub form, the argument) to Numeric, interprets it as radians, returns its cosine.

```
say 0.cos; # 1
say pi.cos; # -1
say cos(pi/2); # 6.12323399573677e-17
```

## routine acos

Defined as:

```
sub acos(Numeric(Cool))
method acos()
```

Usage:

```
acos NUMERIC
NUMERIC.acos
```

Coerces the invocant (or in sub form, the argument) to Numeric, and returns its arc-cosine in radians.

## routine tan

Defined as:

```
sub tan(Numeric(Cool))
method tan()
```

Usage:

```
tan NUMERIC
NUMERIC.tan
```

Coerces the invocant (or in sub form, the argument) to Numeric, interprets it as radians, returns its tangent.

## routine atan

Defined as:

```
sub atan(Numeric(Cool))
method atan()
```

Usage:

```
atan NUMERIC
NUMERIC.atan
```

Coerces the invocant (or in sub form, the argument) to Numeric, and returns its arc-tangent in radians.

## routine atan2

Defined as:

```
sub atan2(Numeric() $x, Numeric() $y = 1e0)
method atan2($y = 1e0)
```

Usage:

```
atan2 NUMERIC, NUMERIC?
NUMERIC.atan2(NUMERIC?)
```

Coerces the arguments (including the invocant in the method form) to Numeric, and returns their two-argument arc-tangent in radians.

## method sec

Defined as:

```
sub sec(Numeric(Cool))
method sec()
```

Usage:

```
sec NUMERIC
NUMERIC.sec
```

Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its secant, that is, the reciprocal of its cosine.

## routine asec

Defined as:

```
sub asec(Numeric(Cool))
method asec()
```

Usage:

```
asec NUMERIC
NUMERIC.asec
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its arc-secant in radians.

## routine cosec

Defined as:

```
sub cosec(Numeric(Cool))
method cosec()
```

Usage:

```
cosec NUMERIC
NUMERIC.cosec
```

Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its cosecant, that is, the reciprocal of its sine.

## routine acosec

Defined as:

```
sub acosec(Numeric(Cool))
method acosec()
```

Usage:

```
acosec NUMERIC
NUMERIC.acosec
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its arc-cosecant in radians.

## routine cotan

Defined as:

```
sub cotan(Numeric(Cool))
method cotan()
```

Usage:

```
cotan NUMERIC
NUMERIC.cotan
```

Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its cotangent, that is, the reciprocal of its tangent.

## routine acotan

Defined as:

```
sub acotan(Numeric(Cool))
method acotan()
```

Usage:

```
acotan NUMERIC
NUMERIC.acotan
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its arc-cotangent in radians.

## routine sinh

Defined as:

```
sub sinh(Numeric(Cool))
method sinh()
```

Usage:

```
sinh NUMERIC
NUMERIC.sinh
```

Coerces the invocant (or in method form, its argument) to Numeric, and returns its Sine hyperbolicus.

## routine asinh

Defined as:

```
sub asinh(Numeric(Cool))
method asinh()
```

Usage:

```
asinh NUMERIC
NUMERIC.asinh
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse Sine hyperbolicus.

## routine cosh

Defined as:

```
sub cosh(Numeric(Cool))
method cosh()
```

Usage:

```
cosh NUMERIC
NUMERIC.cosh
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Cosine hyperbolicus.

## routine acosh

Defined as:

```
sub acosh(Numeric(Cool))
method acosh()
```

Usage:

```
acosh NUMERIC
NUMERIC.acosh
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse Cosine hyperbolicus.

## routine tanh

Defined as:

```
sub tanh(Numeric(Cool))
method tanh()
```

Usage:

```
tanh NUMERIC
NUMERIC.tanh
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Tangent hyperbolicus.

## routine atanh

Defined as:

```
sub atanh(Numeric(Cool))
method atanh()
```

Usage:

```
atanh NUMERIC
NUMERIC.atanh
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse tangent hyperbolicus.

## routine sech

Defined as:

```
sub sech(Numeric(Cool))
method sech()
```

Usage:

```
sech NUMERIC
NUMERIC.sech
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Secant hyperbolicus.

```
say 0.sech; # 1
```

## routine asech

Defined as:

```
sub asech(Numeric(Cool))
method asech()
```

Usage:

```
asech NUMERIC
NUMERIC.asech
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse hyperbolic secant.

```
say 0.8.asech; # 0.693147180559945
```

## routine cosech

Defined as:

```
sub cosech(Numeric(Cool))
method cosech()
```

Usage:

```
cosech NUMERIC
NUMERIC.cosech
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Hyperbolic cosecant.

```
say cosech(pi/2); # 0.434537208094696
```

## routine acosech

Defined as:

```
sub acosech(Numeric(Cool))
method acosech()
```

Usage:

```
acosech NUMERIC
NUMERIC.acosech
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse hyperbolic cosecant.

```
say acosech(4.5); # 0.220432720979802
```

## routine cotanh

Defined as:

```
sub cotanh(Numeric(Cool))
method cotanh()
```

Usage:

```
cotanh NUMERIC
NUMERIC.cotanh
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Hyperbolic cotangent.

```
say cotanh(pi); # 1.00374187319732
```

## routine acotanh

Defined as:

```
sub acotanh(Numeric(Cool))
method acotanh()
```

Usage:

```
acotanh NUMERIC
NUMERIC.acotanh
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse hyperbolic cotangent.

```
say acotanh(2.5); # 0.423648930193602
```

## routine cis

Defined as:

```
sub cis(Numeric(Cool))
method cis()
```

Usage:

```
cis NUMERIC
NUMERIC.cis
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns cos(argument) + i*sin(argument).

```
say cis(pi/4); # 0.707106781186548+0.707106781186547i
```

## routine log

Defined as:

```
multi sub log(Numeric(Cool) $number, Numeric(Cool) $base?)
multi method log(Cool:D: Cool:D $base?)
```

Usage:

```
log NUMERIC, NUMERIC?
NUMERIC.log(NUMERIC?)
```

Coerces the arguments (including the invocant in the method form) to Numeric, and returns its Logarithm to base `$base`

, or to base `e`

(Euler's Number) if no base was supplied (Natural logarithm.

```
say (e*e).log; # 2
```

## routine log10

Defined as:

```
multi sub log10(Cool(Numeric))
multi method log10()
```

Usage:

```
log10 NUMERIC
NUMERIC.log10
```

Coerces the invocant (or in the sub form, the invocant) to Numeric, and returns its Logarithm to base 10, that is, a number that approximately produces the original number when raised to the power of 10.

```
say log10(1001); # 3.00043407747932
```

## method exp

Defined as:

```
multi sub exp(Cool:D $pow, Cool:D $base?)
multi method exp(Cool:D: Cool:D $base?)
```

Usage:

```
exp NUMERIC, NUMERIC?
NUMERIC.exp(NUMERIC?)
```

Coerces the arguments (including the invocant in the method from) to Numeric, and returns `$base`

raised to the power of the first number. If no `$base`

is supplied, `e`

(Euler's Number) is used.

```
say 0.exp; # 1
say 1.exp; # 2.71828182845905
say 10.exp; # 22026.4657948067
```

## method unpolar

Defined as:

```
method unpolar(Numeric(Cool))
```

Usage:

```
unpolar NUMERIC, NUMERIC
NUMERIC.unpolar(NUMERIC)
```

Coerces the arguments (including the invocant in the method form) to Numeric, and returns a complex number from the given polar coordinates. The invocant (or the first argument in sub form) is the magnitude while the argument (i.e. the second argument in sub form) is the angle. The angle is assumed to be in radians.

```
say sqrt(2).unpolar(pi/4); # 1+1i
```

## routine round

Defined as:

```
multi sub round(Numeric(Cool))
multi method round(Cool:D: $unit = 1)
```

Usage:

```
round NUMERIC, NUMERIC?
NUMERIC.round(NUMERIC?)
```

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it to the unit of `$unit`

. If `$unit`

is 1, rounds to the nearest integer.

```
say 1.7.round; # 2
say 1.07.round(0.1); # 1.1
say 21.round(10); # 20
```

## routine floor

Defined as:

```
multi sub floor(Numeric(Cool))
multi method floor
```

Usage:

```
floor NUMERIC
NUMERIC.floor
```

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it downwards to the nearest integer.

```
say "1.99".floor; # 1
say "-1.9".floor; # -2
say 0.floor; # 0
```

## routine ceiling

Defined as:

```
multi sub ceiling(Numeric(Cool))
multi method ceiling
```

Usage:

```
ceiling NUMERIC
NUMERIC.ceiling
```

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it upwards to the nearest integer.

```
say "1".ceiling; # 1
say "-0.9".ceiling; # 0
say "42.1".ceiling; # 43
```

## routine truncate

Defined as:

```
multi sub truncate(Numeric(Cool))
multi method truncate()
```

Usage:

```
truncate NUMERIC
NUMERIC.truncate
```

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it towards zero.

```
say 1.2.truncate # 1
say truncate -1.2; # -1
```

## routine ord

Defined as:

```
sub ord(Str(Cool))
method ord()
```

Usage:

```
ord STRING
STRING.ord
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the Unicode code point number of the first code point.

```
say 'a'.ord; # 97
```

The inverse operation is chr.

Mnemonic: returns an ordinal number

## routine chr

Defined as:

```
sub chr(Int(Cool))
method chr()
```

Usage:

```
chr INTEGER
INTEGER.chr
```

Coerces the invocant (or in sub form, its argument) to Int, interprets it as a Unicode code points, and returns a string made of that code point.

```
say '65'.chr; # A
```

The inverse operation is ord.

Mnemonic: turns an integer into a *char*acter.

## routine chars

Defined as:

```
sub chars(Str(Cool))
method chars()
```

Usage:

```
chars STRING
STRING.chars
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the number of characters in the string. Please note that on the JVM, you currently get codepoints instead of graphemes.

```
say 'møp'.chars; # 3
```

## routine codes

Defined as:

```
sub codes(Str(Cool))
method codes()
```

Usage:

```
codes STRING
STRING.codes
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the number of Unicode code points.

```
say 'møp'.codes; # 3
```

## routine flip

Defined as:

```
sub flip(Str(Cool))
method flip()
```

Usage:

```
flip STRING
STRING.flip
```

Coerces the invocant (or in sub form, its argument) to Str, and returns a reversed version.

```
say 421.flip; # 124
```

## routine trim

Defined as:

```
sub trim(Str(Cool))
method trim()
```

Usage:

```
trim STRING
STRING.trim
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the string with both leading and trailing whitespace stripped.

```
my $stripped = ' abc '.trim;
say "<$stripped>"; # <abc>
```

## routine trim-leading

Defined as:

```
sub trim-leading(Str(Cool))
method trim-leading()
```

Usage:

```
trim-leading STRING
STRING.trim-leading
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the string with leading whitespace stripped.

```
my $stripped = ' abc '.trim-leading;
say "<$stripped>"; # <abc >
```

## routine trim-trailing

Defined as:

```
sub trim-trailing(Str(Cool))
method trim-trailing()
```

Usage:

```
trim-trailing STRING
STRING.trim-trailing
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the string with trailing whitespace stripped.

```
my $stripped = ' abc '.trim-trailing;
say "<$stripped>"; # < abc>
```

## routine lc

Defined as:

```
sub lc(Str(Cool))
method lc()
```

Usage:

```
lc STRING
STRING.lc
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it case-folded to lower case.

```
say "ABC".lc; # abc
```

## routine uc

Defined as:

```
sub uc(Str(Cool))
method uc()
```

Usage:

```
uc STRING
STRING.uc
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it case-folded to upper case (capital letters).

```
say "Abc".uc; # ABC
```

## routine tc

Defined as:

```
sub tc(Str(Cool))
method tc()
```

Usage:

```
tc STRING
STRING.tc
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the first letter case-folded to title case (or where not available, upper case).

```
say "abC".tc; # AbC
```

## routine tclc

Defined as:

```
sub tclc(Str(Cool))
method tclc()
```

Usage:

```
tclc STRING
STRING.tclc
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the first letter case-folded to title case (or where not available, upper case), and the rest of the string case-folded to lower case..

```
say 'abC'.tclc; # Abc
```

## routine wordcase

Defined as:

```
sub wordcase(Str(Cool) $input, :&filter = &tclc, Mu :$where = True)
method wordcase(:&filter = &tclc, Mu :$where = True)
```

Usage:

```
wordcase STRING, FILTER?, WHERE?
STRING.wordcase(FILTER?, WHERE?)
```

Coerces the invocant (or in sub form, the first argument) to Str, and filters each word that smart-matches against `$where`

through the `&filter`

. With the default filter (first character to upper case, rest to lower) and matcher (which accepts everything), this title-cases each word:

```
say "perl 6 programming".wordcase; # Perl 6 Programming
```

With a matcher:

```
say "have fun working on perl".wordcase(:where({ .chars > 3 }));
# Have fun Working on Perl
```

With a customer filter too:

```
say "have fun working on perl".wordcase(:filter(&uc), :where({ .chars > 3 }));
# HAVE fun WORKING on PERL
```

## routine samecase

Defined as:

```
sub samecase(Cool $string, Cool $pattern)
method samecase(Cool:D: Cool $pattern)
```

Usage:

```
samecase STRING, PATTERN
STRING.samecase(PATTERN)
```

Coerces the invocant (or in sub form, the first argument) to Str, and returns a copy of `$string`

with case information for each individual character changed according to `$pattern`

. (The pattern string can contain three types of characters, i.e. uppercase, lowercase and caseless. For a given character in `$pattern`

its case information determines the case of the corresponding character in the result.) If `$string`

is longer than `$pattern`

, the case information from the last character of `$pattern`

is applied to the remaining characters of `$string`

.

```
say "perL 6".samecase("A__a__"); # Perl 6
say "pERL 6".samecase("Ab"); # Perl 6
```

## routine uniname

Defined as:

```
sub uniname(Str(Cool) returns Str
method uniname() returns Str
```

Usage:

```
# Camelia in Unicode
say ‘»ö«’.comb».uniname;
# «("RIGHT-POINTING DOUBLE ANGLE QUOTATION MARK",
"LATIN SMALL LETTER O WITH DIAERESIS", "LEFT-POINTING DOUBLE ANGLE QUOTATION MARK")»
# Find the char with the longest Unicode name.
say (0..0x1FFFF).sort(*.uniname.chars)[*-1].chr.uniname;
# «ARABIC LIGATURE UIGHUR KIRGHIZ YEH WITH HAMZA ABOVE WITH ALEF MAKSURA INITIAL FORM»
```

Interprets the invocant / first argument as a Str, and returns the Unicode codepoint name of the first character. To convert a whole string use uninames.

## routine uninames

Defined as:

```
sub uninames(Str:D)
method uninames()
```

Usage:

```
dd ‘»ö«’.comb».uniname;
# «("RIGHT-POINTING DOUBLE ANGLE QUOTATION MARK",
"LATIN SMALL LETTER O WITH DIAERESIS",
"LEFT-POINTING DOUBLE ANGLE QUOTATION MARK").Seq»
```

Returns of a Seq of unicode names for the Str provided.

## routine chop

Defined as:

```
sub chop(Str(Cool))
method chop()
```

Usage:

```
chop STRING
STRING.chop
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the last character removed.

```
say 'perl'.chop; # per
```

## routine chomp

Defined as:

```
sub chomp(Str(Cool))
method chomp()
```

Usage:

```
chomp STRING
STRING.chomp
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the last character removed, if it is a logical newline.

```
say 'ab'.chomp.chars; # 2
say "a\n".chomp.chars; # 1
```

## routine substr

Defined as:

```
sub substr(Str(Cool) $str, $from, $chars?)
method substr($from, $chars?)
```

Usage:

```
substr(STRING, FROM, CHARS?)
STRING.substr(FROM, CHARS?)
```

Coerces the invocant (or in the sub form, the first argument) to Str, and returns the string starting from offset `$from`

. If `$chars`

is supplied, at most `$chars`

characters are returned.

```
say 'zenith'.substr(2); # nith
say 'zenith'.substr(0, 3); # zen
# works on non-strings too:
say 20151224.substr(6); # 24
# sub form:
say substr "zenith", 0, 3; # zen
```

If the `$from`

parameter is a Callable, it is called with the number of chars in the string as argument. This allows easy indexing relative to the end:

```
say 20151224.substr(*-2); # 24
```

## routine ords

Defined as:

```
sub ords(Str(Cool) $str)
method ords()
```

Usage:

```
ords(STRING)
STRING.ords
```

Coerces the invocant (or in the sub form, the first argument) to Str, and returns a list of Unicode codepoints for each character.

```
say "Perl 6".ords; # 80 101 114 108 32 54
say ords 10; # 49 48
```

This is the list-returning version of ord. The inverse operation in chrs.

## routine chrs

Defined as:

```
sub chrs(*@codepoints) return Str:D
method chrs()
```

Usage:

```
chrs LIST
LIST.chrs
```

Coerces the invocant (or in the sub form, the argument list) to a list of integers, and returns the string created by interpreting each integer as a Unicode codepoint, and joining the characters.

```
say <80 101 114 108 32 54>.chrs; # Perl 6
```

This is the list-input version of chr. The inverse operation is ords.

## routine split

Defined as:

```
multi sub split( Str:D $delimiter, Str(Cool) $input, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
multi sub split(Regex:D $delimiter, Str(Cool) $input, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
multi method split( Str:D $delimiter, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
multi method split(Regex:D $delimiter, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
```

Usage:

```
split DELIMITER, STRING, LIMIT?, [:k | :v | :kv | :p]?, :skip-empty?
split /PATTERN/, STRING, LIMIT?, [:k | :v | :kv | :p]?, :skip-empty?
STRING.split(DELIMITER, LIMIT?, [:k | :v | :kv | :p]?, :skip-empty?)
STRING.split(/PATTERN/, LIMIT?, [:k | :v | :kv | :p]?, :skip-empty?)
```

Coerces the invocant (or in the sub form, the second argument) to Str, and splits it into pieces based on delimiters found in the string.

If `$delimiter`

is a string, it is searched for literally and not treated as a regex.

```
say split(';', "a;b;c").perl; # ("a", "b", "c").list
say split(';', "a;b;c", 2).perl; # ("a", "b;c").list
say split(';', "a;b;c,d").perl; # ("a", "b", "c,d").list
say split(/\;/, "a;b;c,d").perl; # ("a", "b", "c,d").list
say split(/<[;,]>/, "a;b;c,d").perl; # ("a", "b", "c", "d").list
```

By default, split omits the matches, and returns a list of only those parts of the string that did not match. Specifying one of the `:k, :v, :kv, :p`

adverbs changes that. Think of the matches as a list that is interleaved with the non-matching parts. `:v`

interleaves the values of that list: s say 'abc'.split(/b/, :v); # (a ｢b｣ c)

`:k`

interleaves the keys, that is, the indexes:

```
say 'abc'.split(/b/, :k); # (a 0 c)
```

`:kv`

adds both indexes and matches:

```
say 'abc'.split(/b/, :kv); # (a 0 ｢b｣ c)
```

You can only use one of the `:k, :v, :kv, :p`

adverbs in a single call to `split`

.

and `:p`

adds them as Pairs:

```
say 'abc'.split(/b/, :p) # (a 0 => ｢b｣ c)
```

Note that unlike in Perl 5, empty chunks are not removed from the result list. For that behavior, use the `:skip-empty` named argument:

```
say ("f,,b,c,d".split: /","/ ).perl # ("f", "", "b", "c", "d")
say ("f,,b,c,d".split: /","/, :skip-empty).perl # ("f", "b", "c", "d")
```

See also: comb.

## routine lines

Defined as:

```
sub lines(Str(Cool))
method lines()
```

Usage:

```
lines STRING
STRING.lines
```

Coerces the invocant (and in sub form, the argument) to Str, decomposes it into lines (with the newline characters stripped), and returns the list of lines.

```
say lines("a\nb\n").join('|'); # a|b
say "some\nmore\nlines".lines.elems; # 3
```

This method can be used as part of an `IO::Path`

to process a file line-by-line, since `IO::Path`

objects inherit from `Cool`

, e.g.:

```
for 'huge-csv'.IO.lines -> $line {
# Do something with $line
}
# or if you'll be processing later
my @lines = 'huge-csv'.IO.lines;
```

Without any arguments, sub `lines`

operates on `$*ARGFILES`

, which defaults to `$*IN`

in the absence of any filenames.

To modify values in place use `is copy`

to force a writeable container.

```
for $*IN.lines -> $_ is copy { s/(\w+)/{$0 ~ $0}/; .say }
```

## method words

Defined as:

```
method words(Int() $limit)
```

Usage:

```
INTEGER.words(LIMIT?)
```

Coerces the invocant to Str, and returns a list of words that make up the string (and if `$limit`

is supplied, only the first `$limit`

words).

```
say 'The quick brown fox'.words.join('|'); # The|quick|brown|fox
say 'The quick brown fox'.words(2).join('|'); # The|quick
```

Only whitespace counts as word boundaries

```
say "isn't, can't".words.join('|'); # isn't,|can't
```

## routine comb

Defined as:

```
multi sub comb(Regex $matcher, Str(Cool) $input, $limit = *) returns List:D
multi method comb(Regex $matcher, $limit = *) returns List:D
```

Usage:

```
comb /PATTERN/, STRING, LIMIT?
STRING.comb(/PATTERN/, LIMIT?)
```

Returns all (or if supplied, at most `$limit`

) matches of the invocant (method form) or the second argument (sub form) against the Regex as a list of strings.

```
say "6 or 12".comb(/\d+/).join(", "); # 6, 12
```

## method contains

```
multi method contains(Cool:D: Str(Cool) $needle, Cool $start?) returns True:D
```

Returns `True`

if the invocant contains the `$needle`

at any position within the string. If $start is provided skip as many characters.

```
say "Hello, World".contains('hello'); # False
say "Hello, World".contains(','); # True
```

## routine index

Defined as:

```
multi sub index(Str(Cool) $s, Str:D $needle, Int(Cool) $startpos = 0) returns Int
multi method index(Str(Cool) $needle, Int(Cool) $startpos = 0) returns Int
```

Usage:

```
index STRING, NEEDLE, STARTPOS?
STRING.comb(NEEDLE, STARTPOS?)
```

Coerces the first two arguments (in method form, also counting the invocant) to Str, and searches for `$needle`

in the string starting from `$startpos`

. It returns the offset into the string where `$needle`

was found, and an undefined value if it was not found.

See the documentation in type Str for examples.

## routine rindex

Defined as:

```
multi sub rindex(Str(Cool) $haystack, Str(Cool) $needle, Int(Cool) $startpos = $haystack.chars)
multi method rindex(Str(Cool) $haystack: Str(Cool) $needle, Int(Cool) $startpos = $haystack.chars)
```

Usage:

```
rindex STRING, NEEDLE, STARTPOS?
STRING.rindex(NEEDLE, STARTPOS?)
```

Coerces the first two arguments (including the invocant in method form) to Str and `$startpos`

to Int, and returns the last position of `$needle`

in `$haystack`

not after `$startpos`

. Returns an undefined value if `$needle`

wasn't found.

See the documentation in type Str for examples.

## method fmt

Defined as:

```
method fmt($format = '%s') returns Str:D
```

Uses `$format`

to return a formatted representation of the invocant.

For more information about formats strings, see sprintf.

```
say 11.fmt('This Int equals %03d'); # This Int equals 011
say '16'.fmt('Hexadecimal %x'); # Hexadecimal 10
```

## routine roots

Defined as:

```
multi sub roots(Numeric(Cool) $x, Int(Cool) $n)
multi method roots(Int(Cool) $n)
```

Usage:

```
roots NUMERIC, INTEGER
NUMERIC.roots(INTEGER)
```

Coerces the first argument (and in method form, the invocant) to Numeric and the second (`$n`

) to Int, and produces a list of `$n`

Complex `$n`

-roots, which means numbers that, raised to the `$n`

th power, approximately produce the original number.

For example

```
my $original = 16;
my @roots = $original.roots(4);
say @roots;
for @roots -> $r {
say abs($r ** 4 - $original);
}
```

produces this output:

```
2+0i 1.22464679914735e-16+2i -2+2.44929359829471e-16i -3.67394039744206e-16-2i
1.77635683940025e-15
4.30267170434156e-15
8.03651692704705e-15
1.04441561648202e-14
```

## method IO

Defined as:

```
method IO() returns IO::Path:D
```

Usage:

```
EXPR.IO
```

Coerces the invocant to IO::Path.

```
.say for '.'.IO.dir; # gives a directory listing
```

## routine EVAL

Defined as:

```
sub EVAL(Cool $code, :$lang = { ... })
```

Usage:

```
EVAL "say 'hello'";
```

Coerces the invocant to Str.

This works as-is with a literal string parameter. If you have a more complex input, such as a variable or string with embedded code, you must enable the `MONKEY-SEE-NO-EVAL`

pragma:

```
use MONKEY-SEE-NO-EVAL;
EVAL "say { 5 + 5 }"; # says 10
```

Symbols in the current lexical scope are visible to code in an `EVAL`

.

```
my $answer = 42;
EVAL 'say $answer;'; # says 42
```

However, since the set of symbols in a lexical scope is immutable after compile time, an EVAL can never introduce symbols into the surrounding scope.

```
EVAL 'my $lives = 9'; say $lives; # error, $lives not declared
```

Furthermore, the `EVAL`

is evaluated in the current package:

```
module M {
EVAL 'our $answer = 42'
}
say $M::answer; # says 42
```

And also the current language, meaning any added syntax is available:

```
sub infix:<mean>(*@a) is assoc<list> {
@a.sum / @a.elems
}
EVAL 'say 2 mean 6 mean 4'; # says 4
```

An `EVAL`

statement evaluates to the result of the last statement:

```
say EVAL 'say 1; 2 mean 6 mean 4'; # says 1, then says 4
```

`EVAL`

is also a gateway for executing code in other languages:

```
EVAL "use v5.20; say 'Hello from perl5!'", :lang<Perl5>;
```

## routine EVALFILE

Defined as:

```
sub EVALFILE(Cool $filename, :$lang = { ... })
```

Usage:

```
EVALFILE "foo.p6";
```

Slurps the specified file and evaluates it. Behaves the same way as `EVAL`

with regard to both scoping and the `$lang`

parameter. Evaluates to the value produced by the final statement in the file.

# Routines supplied by class Any

Backtrace inherits from class Any, which provides the following methods:

## method ACCEPTS

Defined as:

```
multi method ACCEPTS(Any:D: Mu $other)
```

Usage:

```
EXPR.ACCEPTS(EXPR);
```

Returns `True`

if `$other === self`

(i.e. it checks object identity).

Many built-in types override this for more specific comparisons

## method any

Defined as:

```
method any() returns Junction:D
```

Usage:

```
LIST.any
```

Interprets the invocant as a list and creates an `any`

-Junction from it.

```
say so 2 == <1 2 3>.any; # True
say so 5 == <1 2 3>.any; # False
```

## method all

Defined as:

```
method all() returns Junction:D
```

Usage:

```
LIST.all
```

Interprets the invocant as a list and creates an `all`

-Junction from it.

```
say so 1 < <2 3 4>.all; # True
say so 3 < <2 3 4>.all; # False
```

## method one

Defined as:

```
method one() returns Junction:D
```

Usage:

```
LIST.one
```

Interprets the invocant as a list and creates a `one`

-Junction from it.

```
say so 1 == (1, 2, 3).one; # True
say so 1 == (1, 2, 1).one; # False
```

## method none

Defined as:

```
method none() returns Junction:D
```

Usage:

```
LIST.none
```

Interprets the invocant as a list and creates a `none`

-Junction from it.

```
say so 1 == (1, 2, 3).none; # False
say so 4 == (1, 2, 3).none; # True
```

## method list

Interprets the invocant as a list, and returns that List.

```
say 42.list.^name; # List
say 42.list.elems; # 1
```

## method push

The method push is defined for undefined invocants and allows for autovivifying undefined to an empty `Array`

, unless the undefined value implements `Positional`

already. The argument provided will then be pushed into the newly created Array.

```
my %h;
dd %h<a>; # Any (and therefor undefined)
%h<a>.push(1); # .push on Any
dd %h; # «Hash %h = {:a($[1])}» # please note the Array
```

## routine reverse

Defined as:

```
multi sub reverse(*@list ) returns List:D
multi method reverse(List:D:) returns List:D
```

Usage:

```
reverse(LIST)
LIST.reverse
```

Returns a list with the same elements in reverse order.

Note that `reverse`

always refers to reversing elements of a list; to reverse the characters in a string, use flip.

Examples:

```
say <hello world!>.reverse # world! hello
say reverse ^10 # 9 8 7 6 5 4 3 2 1 0
```

## method sort

Sorts iterables with `infix:<cmp>`

or given code object and returns a new `List`

.

Examples:

```
say <b c a>.sort; # a b c
say 'bca'.comb.sort.join; # abc
say 'bca'.comb.sort({$^b cmp $^a}).join; # cba
say '231'.comb.sort(&infix:«<=>»).join; # 123
```

## method map

Defined as:

```
proto method map(|) is nodal { * }
multi method map(\SELF: █; :$label, :$item)
multi method map(HyperIterable:D: █; :$label)
```

`map`

will iterate over the invocant and apply the number of positional parameters of the code object from the invocant per call. The returned values of the code object will become elements of the returned `Seq`

.

## method deepmap

Defined as:

```
method deepmap(&block -->List) is nodal
```

`deepmap`

will apply `&block`

to each element and return a new `List`

with the return values of `&block`

, unless the element does the `Iterable`

role. For those elements `deepmap`

will descend recursively into the sublist.

```
dd [[1,2,3],[[4,5],6,7]].deepmap(*+1);
# OUTPUT«[[2, 3, 4], [[5, 6], 7, 8]]»
```

## method duckmap

Defined as:

```
method duckmap(&block) is rw is nodal
```

`duckmap`

will apply `&block`

on each element and return a new list with defined return values of the block. For undefined return values, `duckmap`

will try to descend into the element if that element implements `Iterable`

.

```
my @a = [1,[2,3],4];
dd @a.duckmap({ $_ ~~ Int ?? $_++ !! Any });
# OUTPUT«(1, (2, 3), 4)»
```

## method flat

Interprets the invocant as a list, flattens it, and returns that list. Please note that `.flat`

will not solve the halting problem for you. If you flat an infinite list `.flat`

may return that infinite list, eating all your RAM in the process.

```
say ((1, 2), (3)).elems; # 2
say ((1, 2), (3)).flat.elems; # 3
```

Please not that `flat`

is not recursing into sub lists. You have to recurse by hand or reconsider your data structures. A single level of nesting can often be handled with destructuring in signatures. For deeper structures you may consider gather/take to create a lazy list.

```
my @a = [[1,2,3],[[4,5],6,7]];
sub deepflat(@a){
gather for @a {
take ($_ ~~ Iterable ?? deepflat($_).Slip !! $_)
}
};
dd deepflat(@a);'
# OUTPUT«(1, 2, 3, 4, 5, 6, 7).Seq»
```

## method eager

Interprets the invocant as a list, evaluates it eagerly, and returns that list.

```
say (1..10).eager; # 1 2 3 4 5 6 7 8 9 10
```

## method elems

Interprets the invocant as a list, and returns the number of elements in the list.

```
say 42.elems; # 1
say <a b c>.elems; # 3
```

## method end

Interprets the invocant as a list, and returns the last index of that list.

```
say 6.end; # 0
say <a b c>.end; # 2
```

## method pairup

```
method pairup() returns List
```

Interprets the invocant as a list, and constructs a list of pairs from it, in the same way that assignment to a Hash does. That is, it takes two consecutive elements and constructs a pair from them, unless the item in the key position already is a pair (in which case the pair is passed is passed through, and the next list item, if any, is considered to be a key again).

```
say (a => 1, 'b', 'c').pairup.perl; # ("a" => 1, "b" => "c").list
```

## sub exit

```
sub exit(Int() $status = 0)
```

Exits the current process with return code `$status`

.

# Routines supplied by class Mu

Backtrace inherits from class Mu, which provides the following methods:

## routine defined

```
multi sub defined(Mu) returns Bool:D
multi method defined() returns Bool:D
```

Returns `False`

on the type object, and `True`

otherwise.

```
say Int.defined; # False
say 42.defined; # True
```

Very few types (like Failure) override `defined`

to return `False`

even for instances:

```
sub fails() { fail 'oh noe' };
say fails().defined; # False
```

## routine isa

```
multi method isa(Mu $type) returns Bool:D
multi method isa(Str:D $type) returns Bool:D
```

Returns `True`

if the invocant is an instance of class `$type`

, a subset type or a derived class (through inheritance) of `$type`

.

```
my $i = 17;
say $i.isa("Int"); # True
say $i.isa(Any); # True
```

A more idiomatic way to do this is to use the smartmatch operator ~~ instead.

```
my $s = "String";
say $s ~~ Str; # True
```

## routine does

```
method does(Mu $type) returns Bool:D
```

Returns `True`

if and only if the invocant conforms to type `$type`

.

```
my $d = Date.new('2016-06-03');
say $d.does(Dateish); # True (Date does role Dateish)
say $d.does(Any); # True (Date is a subclass of Any)
say $d.does(DateTime); # False (Date is not a subclass of DateTime)
```

Using the smart match operator ~~ is a more idiomatic alternative.

```
my $d = Date.new('2016-06-03');
say $d ~~ Dateish; # True
say $d ~~ Any; # True
say $d ~~ DateTime; # False
```

## routine Bool

```
multi sub Bool(Mu) returns Bool:D
multi method Bool() returns Bool:D
```

Returns `False`

on the type object, and `True`

otherwise.

Many built-in types override this to be `False`

for empty collections, the empty string or numerical zeros

```
say Mu.Bool; # False
say Mu.new.Bool; # True
say [1, 2, 3].Bool; # True
say [].Bool; # False
say { 'hash' => 'full'}.Bool; # True
say {}.Bool; # False
```

## method Str

```
multi method Str() returns Str
```

Returns a string representation of the invocant, intended to be machine readable. Method `Str`

warns on type objects, and produces the empty string.

```
say Mu.Str; #!> use of uninitialized value of type Mu in string context
```

## routine gist

```
multi sub gist(Mu) returns Str
multi method gist() returns Str
```

Returns a string representation of the invocant, optimized for fast recognition by humans. As such lists will be truncated at 100 elements. Use `.perl`

to get all elements.

The default `gist`

method in `Mu`

re-dispatches to the perl method for defined invocants, and returns the type name in parenthesis for type object invocants. Many built-in classes override the case of instances to something more specific that may truncate output.

`gist`

is the method that say calls implicitly, so `say $something`

and `say $something.gist`

generally produce the same output.

```
say Mu.gist; # (Mu)
say Mu.new.gist; # Mu.new()
```

## routine perl

```
multi sub perl(Mu) returns Str
multi method perl() returns Str
```

Returns a Perlish representation of the object (i.e., can usually be re-evaluated with EVAL to regenerate the object). The exact output of `perl`

is implementation specific, since there are generally many ways to write a Perl expression that produces a particular value

## method clone

```
method clone(*%twiddles)
```

Creates a shallow clone of the invocant. If named arguments are passed to it, their values are used in every place where an attribute name matches the name of a named argument.

```
class Point2D {
has ($.x, $.y);
multi method gist(Point2D:D:) {
"Point($.x, $.y)";
}
}
my $p = Point2D.new(x => 2, y => 3);
say $p; # Point(2, 3)
say $p.clone(y => -5); # Point(2, -5)
```

## method new

```
multi method new(*%attrinit)
```

Default method for constructing (create + initialize) new objects of a class. This method expects only named arguments which are then used to initialize attributes with accessors of the same name.

Classes may provide their own `new`

method to override this default.

`new`

triggers an object construction mechanism that calls submethods named `BUILD`

in each class of an inheritance hierarchy, if they exist. See the documentation on object construction for more information.

## method bless

```
method bless(*%attrinit) returns Mu:D
```

Lower-level object construction method than `new`

.

Creates a new object of the same type as the invocant, uses the named arguments to initialize attributes, and returns the created object.

You can use this method when writing custom constructors:

```
class Point {
has $.x;
has $.y;
multi method new($x, $y) {
self.bless(:$x, :$y);
}
}
my $p = Point.new(-1, 1);
```

(Though each time you write a custom constructor, remember that it makes subclassing harder).

## method CREATE

```
method CREATE() returns Mu:D
```

Allocates a new object of the same type as the invocant, without initializing any attributes.

```
say Mu.CREATE.defined; # True
```

## method print

```
multi method print() returns Bool:D
```

Prints value to `$*OUT`

after stringification using `.Str`

method without adding a newline at end.

```
"abc\n".print; # abc
```

## method put

```
multi method put() returns Bool:D
```

Prints value to `$*OUT`

after stringification using `.Str`

method adding a newline at end.

```
"abc".put; # abc
```

## method say

```
multi method say() returns Bool:D
```

Prints value to `$*OUT`

after stringification using `.gist`

method with newline at end. To produce machine readable output use `.put`

.

```
say 42; # 42
```

## method ACCEPTS

```
multi method ACCEPTS(Mu:U: $other)
```

`ACCEPTS`

is the method that smart matching with the infix ~~ operator and given/when invokes on the right-hand side (the matcher).

The `Mu:U`

multi performs a type check. Returns `True`

if `$other`

conforms to the invocant (which is always a type object or failure).

```
say 42 ~~ Mu; # True
say 42 ~~ Int; # True
say 42 ~~ Str; # False
```

Note that there is no multi for defined invocants; this is to allow autothreading of junctions, which happens as a fallback mechanism when no direct candidate is available to dispatch to.

## method WHICH

```
multi method WHICH() returns ObjAt:D
```

Returns an object of type ObjAt which uniquely identifies the object. Value types override this method which makes sure that two equivalent objects return the same return value from `WHICH`

.

```
say 42.WHICH eq 42.WHICH; # True
```

## method WHERE

```
method WHERE() returns Int
```

Returns an `Int`

representing the memory address of the object.

## method WHY

```
multi method WHY()
```

Returns the attached Pod value. For instance,

```
sub cast(Spell $s)
#= Initiate a specified spell normally
#= (do not use for class 7 spells)
{
do-raw-magic($s);
}
say &cast.WHY;
```

prints

```
Initiate a specified spell normally (do not use for class 7 spells)
```

See the documentation specification for details about attaching Pod to variables, classes, functions, methods, etc.

## trait is export

```
multi sub trait_mod:<is>(Mu:U \type, :$export!)
```

Marks a type as being exported, that is, available to external users.

```
my class SomeClass is export { }
```

A user of a module or class automatically gets all the symbols imported that are marked as `is export`

.

See Exporting and Selective Importing Modules for more details.

## method return

```
method return();
```

The method `return`

will stop execution of a subroutine or method, run all relevant phasers and provide invocant as a return value to the caller. If a return type constraint is provided it will be checked unless the return value is `Nil`

. A control exception is raised and can be caught with CONTROL.

```
sub f { (1|2|3).return };
dd f(); # OUTPUT«any(1, 2, 3)»
```

## method return-rw

Same as method `return`

but provides the invocant as a writeable container to the invocant.

## method take

```
method take()
```

Takes the given item and passes it to the enclosing `gather`

block.

```
#| randomly select numbers for lotto
my $num-selected-numbers = 6;
my $max-lotto-numbers = 49;
gather for ^$num-selected-numbers {
take (1 .. $max-lotto-numbers).pick(1);
}.say; #-> 32 22 1 17 32 9 (for example)
```

## method so

```
method so()
```

Returns a `Bool`

value representing the logical non-negation of an expression. One can use this method similarly to the English sentence: "If that is **so**, then do this thing". For instance,

```
my @args = <-a -e -b -v>;
my $verbose-selected = any(@args) eq '-v' | '-V';
if $verbose-selected.so {
say "Verbose option detected in arguments";
} #-> Verbose option detected in arguments
```

## method not

```
method not()
```

Returns a `Bool`

value representing the logical negation of an expression. Thus it is the opposite of `so`

.

```
my @args = <-a -e -b>;
my $verbose-selected = any(@args) eq '-v' | '-V';
if $verbose-selected.not {
say "Verbose option not present in arguments";
} #-> Verbose option not present in arguments
```

Since there is also a prefix version of `not`

, the above code reads better like so:

```
my @args = <-a -e -b>;
my $verbose-selected = any(@args) eq '-v' | '-V';
if not $verbose-selected {
say "Verbose option not present in arguments";
} #-> Verbose option not present in arguments
```