# class FatRat

Rational number (arbitrary-precision)

```
class FatRat is Cool does Rational[Int, Int] {}
```

A `FatRat`

is a rational number stored with arbitrary size numerator and denominator. Arithmetic operations involving a `FatRat`

and optionally Int or Rat objects return a `FatRat`

, avoiding loss of precision.

Since, unlike Rat, FatRat arithmetics do not fall back Num at some point, there is a risk that repeated arithmetic operations generate pathologically large numerators and denominators.

There are two common ways to generate `FatRat`

objects: through the `FatRat.new(Int, Int)`

constructor, which generates them from numerator and denominator, or by calling the `.FatRat`

method on an Int or Rat object.

# Type graph

# Routines supplied by role Rational

FatRat does role Rational, which provides the following methods:

## (Rational) method new

```
method new(NuT:D: $numerator, DeT:D: $denominator) returns Rational:D
```

Creates a new rational object from numerator and denominator.

## (Rational) method numerator

```
method numerator(Rational:D:) returns NuT:D
```

Returns the numerator.

## (Rational) method denominator

```
method denominator(Rational:D:) returns DeT:D
```

Returns the denominator.

## (Rational) method nude

```
method nude(Rational:D:) returns Positional
```

Returns a list of the numerator and denominator.

## (Rational) method norm

```
method norm(Rational:D:) returns Rational:D
```

Returns a normalized Rational object, i.e. with positive denominator, and numerator and denominator coprime.

## (Rational) method base-repeating

```
method base-repeating(Rational:D: Int:D() $base)
```

Returns a list of two strings that, when concatenated, represent the number in base `$base`

. The second element is the one that repeats. For example:

```
my ($non-rep, $repeating) = (19/3).base-repeating(10);
say $non-rep; # 6.
say $repeating; # 3
printf '%s(%s)', $non-rep, $repeating; # 6.(3)
```

19/3 is 6.333333... with the 3 repeating indefinitely.

If no repetition occurs, the second string is empty:

```
say (5/2).base-repeating(10).perl; # ("2.5", "")
```

The precision for determining the repeating group is limited to 1000 characters, above that, the second string is `???`

.

# Routines supplied by role Real

FatRat does role Real, which provides the following methods:

## (Real) method Rat

```
method Rat(Real:D: Real $epsilon = 1e-6)
```

Converts the number to a `Rat`

with the precision `$epsilon`

.

## (Real) routine rand

```
sub term:<rand> returns Num:D
method rand(Real:D:) returns Real:D
```

Returns a pseudo-random number between zero and the number.

The term form returns a pseudo-random `Num`

between 0e0 and 1e0.

## (Real) method sign

```
method sign(Real:D:)
```

Returns `-1`

if the number is negative, `0`

if it is zero and `1`

otherwise.

## (Real) method round

```
method round(Real:D: $scale = 1)
```

Rounds the number to scale `$scale`

. If `$scale`

is 1, rounds to an integer. If scale is `0.1`

, rounds to one digit after the comma etc.

## (Real) method floor

```
method floor(Real:D) returns Int:D
```

Return the largest integer not greater than the number.

## (Real) method ceiling

```
method ceiling(Real:D) returns Int:D
```

Returns the smallest integer not less than the number.

## (Real) method truncate

```
method truncate(Real:D) returns Int:D
```

Rounds the number towards zero.

## (Real) method base

```
method base(Real:D: Int:D $base where 2..36, $digits?) returns Str:D
```

Converts the number to a string, using `$base`

as base. For `$base`

larger than ten, capital Latin letters are used.

```
255.base(16); # 'FF'
```

The optional `$digits`

argument asks for that many digits of fraction (which may not be negative). If omitted, a reasonable default is chosen based on type. For Int this default is 0. For Num, the default is 8. For Rational, the number of places is scaled to the size of the denominator, with a minimum of 6.

The final digit produced is always rounded.

```
say pi.base(10, 5); # 3.14159
```

To convert a string to a number use the `:16($string)`

notation where 16 is the base:

```
say :16("FF"); # 255
say :23("FF"); # 360
```

# Routines supplied by role Numeric

FatRat does role Numeric, which provides the following methods:

## (Numeric) method Real

```
method Real(Numeric:D:) returns Real:D
```

If this `Numeric`

is equivalent to a `Real`

, return that `Real`

. Fail with `X::Numeric::Real`

otherwise.

## (Numeric) method Int

```
method Int(Numeric:D:) returns Int:D
```

If this `Numeric`

is equivalent to a `Real`

, return the equivalent of calling `truncate`

on that `Real`

to get an `Int`

. Fail with `X::Numeric::Real`

otherwise.

## (Numeric) method Rat

```
method Rat(Numeric:D: Real $epsilon = 1.0e-6) returns Rat:D
```

If this `Numeric`

is equivalent to a `Real`

, return a `Rat`

which is within `$epsilon`

of that `Real`

's value. Fail with `X::Numeric::Real`

otherwise.

## (Numeric) method Num

```
method Num(Numeric:D:) returns Num:D
```

If this `Numeric`

is equivalent to a `Real`

, return that `Real`

as a `Num`

as accurately as is possible. Fail with `X::Numeric::Real`

otherwise.

## (Numeric) method narrow

```
method narrow(Numeric:D) returns Numeric:D
```

Returns the number converted to the narrowest type that can hold it without loss of precision.

```
say (4.0 + 0i).narrow.perl; # 4
say (4.0 + 0i).narrow.^name; # Int
```

## (Numeric) method ACCEPTS

```
multi method ACCEPTS(Numeric:D: $other)
```

Returns True if `$other`

is numerically the same as the invocant.

## (Numeric) routine log

```
multi sub log(Numeric:D, Numeric $base = e) returns Numeric:D
multi method log(Numeric:D: Numeric $base = e) returns Numeric:D
```

Calculates the logarithm to base `$base`

. Defaults to the natural logarithm.

## (Numeric) routine log10

```
multi sub log10(Numeric:D ) returns Numeric:D
multi method log10(Numeric:D:) returns Numeric:D
```

Calculates the logarithm to base 10.

## (Numeric) routine exp

```
multi sub exp(Numeric:D, Numeric:D $base = e) returns Numeric:D
multi method exp(Numeric:D: Numeric:D $base = e) returns Numeric:D
```

Returns `$base`

to the power of the number, or `e`

to the power of the number if called without a second argument.

## (Numeric) method roots

```
multi method roots(Numeric:D: Int:D $n) returns Positional
```

Returns a list of the `$n`

complex roots, which evaluate to the original number when raised to the `$n`

th power.

## (Numeric) routine abs

```
multi sub abs(Numeric:D ) returns Real:D
multi method abs(Numeric:D:) returns Real:D
```

Returns the absolute value of the number.

## (Numeric) routine sqrt

```
multi sub sqrt(Numeric:D) returns Numeric:D
multi method sqrt(Numeric:D) returns Numeric:D
```

Returns a square root of the number. For real numbers the positive square root is returned.

On negative real numbers, `sqrt`

returns `NaN`

rather than a complex number, in order to not confuse people who are not familiar with complex arithmetic. If you want to calculate complex square roots, coerce to `Complex`

first, or use the `roots`

method.

## (Numeric) method conj

```
multi method conj(Numeric:D) returns Numeric:D
```

Returns the complex conjugate of the number. Returns the number itself for real numbers.

## (Numeric) method Bool

```
multi method Bool(Numeric:D:)
```

Returns `False`

if the number is equivalent to zero, and `True`

otherwise.

## (Numeric) method succ

```
method succ(Numeric:D:)
```

Returns the number incremented by one (successor).

## (Numeric) method pred

```
method pred(Numeric:D:)
```

Returns the number decremented by one (predecessor).

# Routines supplied by class Cool

FatRat inherits from class Cool, which provides the following methods:

## (Cool) routine abs

Defined as:

```
sub abs(Numeric() $x)
method abs()
```

Coerces the invocant (or in the sub form, the argument) to Numeric and returns the absolute value (that is, a non-negative number).

```
say (-2).abs; # 2
say abs "6+8i"; # 10
```

## (Cool) method conj

Defined as:

```
method conj()
```

Coerces the invocant to Numeric and returns the complex conjugate (that is, the number with the sign of the imaginary part negated).

```
say (1+2i).conj; # 1-2i
```

## (Cool) routine sqrt

Defined as:

```
sub sqrt(Numeric(Cool) $x)
method sqrt()
```

Coerces the invocant to Numeric (or in the sub form, the argument) and returns the square root, that is, a non-negative number that, when multiplied with itself, produces the original number.

```
say 4.sqrt; # 2
say sqrt(2); # 1.4142135623731
```

## (Cool) method sign

Defined as:

```
method sign()
```

Coerces the invocant to Numeric and returns its sign, that is, 0 if the number is 0, 1 for positive and -1 for negative values.

```
say 6.sign; # 1
say (-6).sign; # -1
say "0".sign; # 0
```

## (Cool) method rand

Defined as:

```
method rand()
```

Coerces the invocant to Num and returns a pseudo-random value between zero and the number.

```
say 1e5.rand; # 33128.495184283
```

## (Cool) routine sin

Defined as:

```
sub sin(Numeric(Cool))
method sin()
```

Coerces the invocant (or in the sub form, the argument) to Numeric, interprets it as radians, returns its sine.

```
say sin(0); # 0
say sin(pi/4); # 0.707106781186547
say sin(pi/2); # 1
```

Note that Perl 6 is no computer algebra system, so `sin(pi)`

typically does not produce an exact 0, but rather a very small floating-point number.

## (Cool) routine asin

Defined as:

```
sub asin(Numeric(Cool))
method asin()
```

Coerces the invocant (or in the sub form, the argument) to Numeric, and returns its arc-sine in radians.

```
say 0.1.asin; # 0.10016742116156
say asin(0.1); # 0.10016742116156
```

## (Cool) routine cos

Defined as:

```
sub cos(Numeric(Cool))
method cos()
```

Coerces the invocant (or in sub form, the argument) to Numeric, interprets it as radians, returns its cosine.

```
say 0.cos; # 1
say pi.cos; # -1
say cos(pi/2); # 6.12323399573677e-17
```

## (Cool) routine acos

Defined as:

```
sub acos(Numeric(Cool))
method acos()
```

Coerces the invocant (or in sub form, the argument) to Numeric, and returns its arc-cosine in radians.

## (Cool) routine tan

Defined as:

```
sub tan(Numeric(Cool))
method tan()
```

Coerces the invocant (or in sub form, the argument) to Numeric, interprets it as radians, returns its tangent.

```
say tan(3); # -0.142546543074278
say 3.tan; # -0.142546543074278
```

## (Cool) routine atan

Defined as:

```
sub atan(Numeric(Cool))
method atan()
```

Coerces the invocant (or in sub form, the argument) to Numeric, and returns its arc-tangent in radians.

```
say atan(3); # 1.24904577239825
say 3.atan; # 1.24904577239825
```

## (Cool) routine atan2

Defined as:

```
sub atan2(Numeric() $x, Numeric() $y = 1e0)
method atan2($y = 1e0)
```

Coerces the arguments (including the invocant in the method form) to Numeric, and returns their two-argument arc-tangent in radians.

```
say atan2(3); # 1.24904577239825
say 3.atan2; # 1.24904577239825
```

## (Cool) method sec

Defined as:

```
sub sec(Numeric(Cool))
method sec()
```

Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its secant, that is, the reciprocal of its cosine.

```
say 45.sec; # 1.90359440740442
say sec(45); # 1.90359440740442
```

## (Cool) routine asec

Defined as:

```
sub asec(Numeric(Cool))
method asec()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its arc-secant in radians.

```
say 0.45.sec; # 1.11055940697373
say sec(0.45); # 1.11055940697373
```

## (Cool) routine cosec

Defined as:

```
sub cosec(Numeric(Cool))
method cosec()
```

Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its cosecant, that is, the reciprocal of its sine.

```
say 0.45.cosec; # 2.29903273150897
say cosec(0.45); # 2.29903273150897
```

## (Cool) routine acosec

Defined as:

```
sub acosec(Numeric(Cool))
method acosec()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its arc-cosecant in radians.

```
say 45.acosec; # 0.0222240516182672
say acosec(45) # 0.0222240516182672
```

## (Cool) routine cotan

Defined as:

```
sub cotan(Numeric(Cool))
method cotan()
```

Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its cotangent, that is, the reciprocal of its tangent.

```
say 45.cotan; # 0.617369623783555
say cotan(45); # 0.617369623783555
```

## (Cool) routine acotan

Defined as:

```
sub acotan(Numeric(Cool))
method acotan()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its arc-cotangent in radians.

```
say 45.acotan; # 0.0222185653267191
say acotan(45) # 0.0222185653267191
```

## (Cool) routine sinh

Defined as:

```
sub sinh(Numeric(Cool))
method sinh()
```

Coerces the invocant (or in method form, its argument) to Numeric, and returns its Sine hyperbolicus.

```
say 1.sinh; # 1.1752011936438
say sinh(1); # 1.1752011936438
```

## (Cool) routine asinh

Defined as:

```
sub asinh(Numeric(Cool))
method asinh()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse Sine hyperbolicus.

```
say 1.asinh; # 0.881373587019543
say asinh(1); # 0.881373587019543
```

## (Cool) routine cosh

Defined as:

```
sub cosh(Numeric(Cool))
method cosh()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Cosine hyperbolicus.

```
say cosh(0.5); # 1.12762596520638
```

## (Cool) routine acosh

Defined as:

```
sub acosh(Numeric(Cool))
method acosh()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse Cosine hyperbolicus.

```
say acosh(45); # 4.4996861906715
```

## (Cool) routine tanh

Defined as:

```
sub tanh(Numeric(Cool))
method tanh()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Tangent hyperbolicus.

```
say tanh(30); # 30
```

## (Cool) routine atanh

Defined as:

```
sub atanh(Numeric(Cool))
method atanh()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse tangent hyperbolicus.

```
say atanh(0.5); # 0.549306144334055
```

## (Cool) routine sech

Defined as:

```
sub sech(Numeric(Cool))
method sech()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Secant hyperbolicus.

```
say 0.sech; # 1
```

## (Cool) routine asech

Defined as:

```
sub asech(Numeric(Cool))
method asech()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse hyperbolic secant.

```
say 0.8.asech; # 0.693147180559945
```

## (Cool) routine cosech

Defined as:

```
sub cosech(Numeric(Cool))
method cosech()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Hyperbolic cosecant.

```
say cosech(pi/2); # 0.434537208094696
```

## (Cool) routine acosech

Defined as:

```
sub acosech(Numeric(Cool))
method acosech()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse hyperbolic cosecant.

```
say acosech(4.5); # 0.220432720979802
```

## (Cool) routine cotanh

Defined as:

```
sub cotanh(Numeric(Cool))
method cotanh()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Hyperbolic cotangent.

```
say cotanh(pi); # 1.00374187319732
```

## (Cool) routine acotanh

Defined as:

```
sub acotanh(Numeric(Cool))
method acotanh()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its Inverse hyperbolic cotangent.

```
say acotanh(2.5); # 0.423648930193602
```

## (Cool) routine cis

Defined as:

```
sub cis(Numeric(Cool))
method cis()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and returns cos(argument) + i*sin(argument).

```
say cis(pi/4); # 0.707106781186548+0.707106781186547i
```

## (Cool) routine log

Defined as:

```
multi sub log(Numeric(Cool) $number, Numeric(Cool) $base?)
multi method log(Cool:D: Cool:D $base?)
```

Coerces the arguments (including the invocant in the method form) to Numeric, and returns its Logarithm to base `$base`

, or to base `e`

(Euler's Number) if no base was supplied (Natural logarithm.

```
say (e*e).log; # 2
```

## (Cool) routine log10

Defined as:

```
multi sub log10(Cool(Numeric))
multi method log10()
```

Coerces the invocant (or in the sub form, the invocant) to Numeric, and returns its Logarithm to base 10, that is, a number that approximately produces the original number when raised to the power of 10.

```
say log10(1001); # 3.00043407747932
```

## (Cool) method exp

Defined as:

```
multi sub exp(Cool:D $pow, Cool:D $base?)
multi method exp(Cool:D: Cool:D $base?)
```

Coerces the arguments (including the invocant in the method from) to Numeric, and returns `$base`

raised to the power of the first number. If no `$base`

is supplied, `e`

(Euler's Number) is used.

```
say 0.exp; # 1
say 1.exp; # 2.71828182845905
say 10.exp; # 22026.4657948067
```

## (Cool) method unpolar

Defined as:

```
method unpolar(Numeric(Cool))
```

Coerces the arguments (including the invocant in the method form) to Numeric, and returns a complex number from the given polar coordinates. The invocant (or the first argument in sub form) is the magnitude while the argument (i.e. the second argument in sub form) is the angle. The angle is assumed to be in radians.

```
say sqrt(2).unpolar(pi/4); # 1+1i
```

## (Cool) routine round

Defined as:

```
multi sub round(Numeric(Cool))
multi method round(Cool:D: $unit = 1)
```

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it to the unit of `$unit`

. If `$unit`

is 1, rounds to the nearest integer.

```
say 1.7.round; # 2
say 1.07.round(0.1); # 1.1
say 21.round(10); # 20
```

## (Cool) routine floor

Defined as:

```
multi sub floor(Numeric(Cool))
multi method floor
```

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it downwards to the nearest integer.

```
say "1.99".floor; # 1
say "-1.9".floor; # -2
say 0.floor; # 0
```

## (Cool) routine ceiling

Defined as:

```
multi sub ceiling(Numeric(Cool))
multi method ceiling
```

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it upwards to the nearest integer.

```
say "1".ceiling; # 1
say "-0.9".ceiling; # 0
say "42.1".ceiling; # 43
```

## (Cool) routine truncate

Defined as:

```
multi sub truncate(Numeric(Cool))
multi method truncate()
```

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it towards zero.

```
say 1.2.truncate; # 1
say truncate -1.2; # -1
```

## (Cool) routine ord

Defined as:

```
sub ord(Str(Cool))
method ord()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the Unicode code point number of the first code point.

```
say 'a'.ord; # 97
```

The inverse operation is chr.

Mnemonic: returns an ordinal number

## (Cool) routine chr

Defined as:

```
sub chr(Int(Cool))
method chr()
```

Coerces the invocant (or in sub form, its argument) to Int, interprets it as a Unicode code points, and returns a string made of that code point.

```
say '65'.chr; # A
```

The inverse operation is ord.

Mnemonic: turns an integer into a *char*acter.

## (Cool) routine chars

Defined as:

```
sub chars(Str(Cool))
method chars()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the number of characters in the string. Please note that on the JVM, you currently get codepoints instead of graphemes.

```
say 'møp'.chars; # 3
```

## (Cool) routine codes

Defined as:

```
sub codes(Str(Cool))
method codes()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the number of Unicode code points.

```
say 'møp'.codes; # 3
```

## (Cool) routine flip

Defined as:

```
sub flip(Str(Cool))
method flip()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns a reversed version.

```
say 421.flip; # 124
```

## (Cool) routine trim

Defined as:

```
sub trim(Str(Cool))
method trim()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the string with both leading and trailing whitespace stripped.

```
my $stripped = ' abc '.trim;
say "<$stripped>"; # <abc>
```

## (Cool) routine trim-leading

Defined as:

```
sub trim-leading(Str(Cool))
method trim-leading()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the string with leading whitespace stripped.

```
my $stripped = ' abc '.trim-leading;
say "<$stripped>"; # <abc >
```

## (Cool) routine trim-trailing

Defined as:

```
sub trim-trailing(Str(Cool))
method trim-trailing()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns the string with trailing whitespace stripped.

```
my $stripped = ' abc '.trim-trailing;
say "<$stripped>"; # < abc>
```

## (Cool) routine lc

Defined as:

```
sub lc(Str(Cool))
method lc()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it case-folded to lower case.

```
say "ABC".lc; # abc
```

## (Cool) routine uc

Defined as:

```
sub uc(Str(Cool))
method uc()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it case-folded to upper case (capital letters).

```
say "Abc".uc; # ABC
```

## (Cool) routine tc

Defined as:

```
sub tc(Str(Cool))
method tc()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the first letter case-folded to title case (or where not available, upper case).

```
say "abC".tc; # AbC
```

## (Cool) routine tclc

Defined as:

```
sub tclc(Str(Cool))
method tclc()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the first letter case-folded to title case (or where not available, upper case), and the rest of the string case-folded to lower case..

```
say 'abC'.tclc; # Abc
```

## (Cool) routine wordcase

Defined as:

```
sub wordcase(Str(Cool) $input, :&filter = &tclc, Mu :$where = True)
method wordcase(:&filter = &tclc, Mu :$where = True)
```

Coerces the invocant (or in sub form, the first argument) to Str, and filters each word that smart-matches against `$where`

through the `&filter`

. With the default filter (first character to upper case, rest to lower) and matcher (which accepts everything), this title-cases each word:

```
say "perl 6 programming".wordcase; # Perl 6 Programming
```

With a matcher:

```
say "have fun working on perl".wordcase(:where({ .chars > 3 }));
# Have fun Working on Perl
```

With a customer filter too:

```
say "have fun working on perl".wordcase(:filter(&uc), :where({ .chars > 3 }));
# HAVE fun WORKING on PERL
```

## (Cool) routine samecase

Defined as:

```
sub samecase(Cool $string, Cool $pattern)
method samecase(Cool:D: Cool $pattern)
```

Coerces the invocant (or in sub form, the first argument) to Str, and returns a copy of `$string`

with case information for each individual character changed according to `$pattern`

. (The pattern string can contain three types of characters, i.e. uppercase, lowercase and caseless. For a given character in `$pattern`

its case information determines the case of the corresponding character in the result.) If `$string`

is longer than `$pattern`

, the case information from the last character of `$pattern`

is applied to the remaining characters of `$string`

.

```
say "perL 6".samecase("A__a__"); # Perl 6
say "pERL 6".samecase("Ab"); # Perl 6
```

## (Cool) routine uniname

Defined as:

```
sub uniname(Str(Cool)) returns Str
method uniname() returns Str
```

Interprets the invocant / first argument as a Str, and returns the Unicode codepoint name of the first character. To convert a whole string use uninames.

```
# Camelia in Unicode
say ‘»ö«’.comb».uniname;
# «("RIGHT-POINTING DOUBLE ANGLE QUOTATION MARK",
# "LATIN SMALL LETTER O WITH DIAERESIS", "LEFT-POINTING DOUBLE ANGLE QUOTATION MARK")»
# Find the char with the longest Unicode name.
say (0..0x1FFFF).sort(*.uniname.chars)[*-1].chr.uniname;
# «ARABIC LIGATURE UIGHUR KIRGHIZ YEH WITH HAMZA ABOVE WITH ALEF MAKSURA INITIAL FORM»
```

## (Cool) routine uninames

Defined as:

```
sub uninames(Str:D)
method uninames()
```

Returns of a Seq of unicode names for the Str provided.

```
dd ‘»ö«’.comb».uniname;
# «("RIGHT-POINTING DOUBLE ANGLE QUOTATION MARK",
# "LATIN SMALL LETTER O WITH DIAERESIS",
# "LEFT-POINTING DOUBLE ANGLE QUOTATION MARK").Seq»
```

## (Cool) routine chop

Defined as:

```
sub chop(Str(Cool))
method chop()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the last character removed.

```
say 'perl'.chop; # per
```

## (Cool) routine chomp

Defined as:

```
sub chomp(Str(Cool))
method chomp()
```

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the last character removed, if it is a logical newline.

```
say 'ab'.chomp.chars; # 2
say "a\n".chomp.chars; # 1
```

## (Cool) routine substr

Defined as:

```
sub substr(Str(Cool) $str, $from, $chars?)
method substr($from, $chars?)
```

Coerces the invocant (or in the sub form, the first argument) to Str, and returns the string starting from offset `$from`

. If `$chars`

is supplied, at most `$chars`

characters are returned.

```
say 'zenith'.substr(2); # nith
say 'zenith'.substr(0, 3); # zen
# works on non-strings too:
say 20151224.substr(6); # 24
# sub form:
say substr "zenith", 0, 3; # zen
```

If the `$from`

parameter is a Callable, it is called with the number of chars in the string as argument. This allows easy indexing relative to the end:

```
say 20151224.substr(*-2); # 24
```

## (Cool) routine ords

Defined as:

```
sub ords(Str(Cool) $str)
method ords()
```

Coerces the invocant (or in the sub form, the first argument) to Str, and returns a list of Unicode codepoints for each character.

```
say "Perl 6".ords; # 80 101 114 108 160 54
say ords 10; # 49 48
```

This is the list-returning version of ord. The inverse operation in chrs.

## (Cool) routine chrs

Defined as:

```
sub chrs(*@codepoints) returns Str:D
method chrs()
```

Coerces the invocant (or in the sub form, the argument list) to a list of integers, and returns the string created by interpreting each integer as a Unicode codepoint, and joining the characters.

```
say <80 101 114 108 160 54>.chrs; # Perl 6
```

This is the list-input version of chr. The inverse operation is ords.

## (Cool) routine split

Defined as:

```
multi sub split( Str:D $delimiter, Str(Cool) $input, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
multi sub split(Regex:D $delimiter, Str(Cool) $input, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
multi method split( Str:D $delimiter, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
multi method split(Regex:D $delimiter, $limit = Inf, :$k, :$v, :$kv, :$p, :$skip-empty)
```

Coerces the invocant (or in the sub form, the second argument) to Str, and splits it into pieces based on delimiters found in the string.

If `$delimiter`

is a string, it is searched for literally and not treated as a regex.

```
say split(';', "a;b;c").perl; # ("a", "b", "c")
say split(';', "a;b;c", 2).perl; # ("a", "b;c").Seq
say split(';', "a;b;c,d").perl; # ("a", "b", "c,d")
say split(/\;/, "a;b;c,d").perl; # ("a", "b", "c,d")
say split(/<[;,]>/, "a;b;c,d").perl; # ("a", "b", "c", "d")
```

By default, split omits the matches, and returns a list of only those parts of the string that did not match. Specifying one of the `:k, :v, :kv, :p`

adverbs changes that. Think of the matches as a list that is interleaved with the non-matching parts. `:v`

interleaves the values of that list:

```
say 'abc'.split(/b/, :v); # (a ｢b｣ c)
```

`:k`

interleaves the keys, that is, the indexes:

```
say 'abc'.split(/b/, :k); # (a 0 c)
```

`:kv`

adds both indexes and matches:

```
say 'abc'.split(/b/, :kv); # (a 0 ｢b｣ c)
```

You can only use one of the `:k, :v, :kv, :p`

adverbs in a single call to `split`

.

and `:p`

adds them as Pairs:

```
say 'abc'.split(/b/, :p) # (a 0 => ｢b｣ c)
```

Note that unlike in Perl 5, empty chunks are not removed from the result list. For that behavior, use the `:skip-empty` named argument:

```
say ("f,,b,c,d".split: /","/ ).perl; # ("f", "", "b", "c", "d")
say ("f,,b,c,d".split: /","/, :skip-empty).perl; # ("f", "b", "c", "d")
```

See also: comb.

## (Cool) routine lines

Defined as:

```
sub lines(Str(Cool))
method lines()
```

Coerces the invocant (and in sub form, the argument) to Str, decomposes it into lines (with the newline characters stripped), and returns the list of lines.

```
say lines("a\nb\n").join('|'); # a|b
say "some\nmore\nlines".lines.elems; # 3
```

This method can be used as part of an `IO::Path`

to process a file line-by-line, since `IO::Path`

objects inherit from `Cool`

, e.g.:

```
'huge-csv'.IO.lines -> $line {
# Do something with $line
}
# or if you'll be processing later
my @lines = 'huge-csv'.IO.lines;
```

Without any arguments, sub `lines`

operates on `$*ARGFILES`

, which defaults to `$*IN`

in the absence of any filenames.

To modify values in place use `is copy`

to force a writeable container.

```
for $*IN.lines -> $_ is copy { s/(\w+)/{$0 ~ $0}/; .say }
```

## (Cool) method words

Defined as:

```
method words(Int() $limit)
```

Coerces the invocant to Str, and returns a list of words that make up the string (and if `$limit`

is supplied, only the first `$limit`

words).

```
say 'The quick brown fox'.words.join('|'); # The|quick|brown|fox
say 'The quick brown fox'.words(2).join('|'); # The|quick
```

Only whitespace counts as word boundaries

```
say "isn't, can't".words.join('|'); # isn't,|can't
```

## (Cool) routine comb

Defined as:

```
multi sub comb(Regex $matcher, Str(Cool) $input, $limit = *) returns List:D
multi method comb(Regex $matcher, $limit = *) returns List:D
```

Returns all (or if supplied, at most `$limit`

) matches of the invocant (method form) or the second argument (sub form) against the Regex as a list of strings.

```
say "6 or 12".comb(/\d+/).join(", "); # 6, 12
```

## (Cool) method contains

```
multi method contains(Cool:D: Str(Cool) $needle, Cool $start?) returns True:D
```

Returns `True`

if the invocant contains the `$needle`

at any position within the string. If $start is provided skip as many characters.

```
say "Hello, World".contains('hello'); # False
say "Hello, World".contains(','); # True
```

## (Cool) routine index

Defined as:

```
multi sub index(Str(Cool) $s, Str:D $needle, Int(Cool) $startpos = 0) returns Int
multi method index(Str(Cool) $needle, Int(Cool) $startpos = 0) returns Int
```

Coerces the first two arguments (in method form, also counting the invocant) to Str, and searches for `$needle`

in the string starting from `$startpos`

. It returns the offset into the string where `$needle`

was found, and an undefined value if it was not found.

See the documentation in type Str for examples.

## (Cool) routine rindex

Defined as:

```
multi sub rindex(Str(Cool) $haystack, Str(Cool) $needle, Int(Cool) $startpos = $haystack.chars)
multi method rindex(Str(Cool) $haystack: Str(Cool) $needle, Int(Cool) $startpos = $haystack.chars)
```

Coerces the first two arguments (including the invocant in method form) to Str and `$startpos`

to Int, and returns the last position of `$needle`

in `$haystack`

not after `$startpos`

. Returns an undefined value if `$needle`

wasn't found.

See the documentation in type Str for examples.

## (Cool) method fmt

Defined as:

```
method fmt($format = '%s') returns Str:D
```

Uses `$format`

to return a formatted representation of the invocant.

For more information about formats strings, see sprintf.

```
say 11.fmt('This Int equals %03d'); # This Int equals 011
say '16'.fmt('Hexadecimal %x'); # Hexadecimal 10
```

## (Cool) routine roots

Defined as:

```
multi sub roots(Numeric(Cool) $x, Int(Cool) $n)
multi method roots(Int(Cool) $n)
```

Coerces the first argument (and in method form, the invocant) to Numeric and the second (`$n`

) to Int, and produces a list of `$n`

Complex `$n`

-roots, which means numbers that, raised to the `$n`

th power, approximately produce the original number.

For example

```
my $original = 16;
my @roots = $original.roots(4);
say @roots;
for @roots -> $r {
say abs($r ** 4 - $original);
}
```

produces this output:

```
2+0i 1.22464679914735e-16+2i -2+2.44929359829471e-16i -3.67394039744206e-16-2i
1.77635683940025e-15
4.30267170434156e-15
8.03651692704705e-15
1.04441561648202e-14
```

## (Cool) method IO

Defined as:

```
method IO() returns IO::Path:D
```

Coerces the invocant to IO::Path.

```
.say for '.'.IO.dir; # gives a directory listing
```

## (Cool) routine EVAL

Defined as:

```
sub EVAL(Cool $code, :$lang = { ... })
```

Coerces the invocant to Str.

This works as-is with a literal string parameter. If you have a more complex input, such as a variable or string with embedded code, you must enable the `MONKEY-SEE-NO-EVAL`

pragma:

```
use MONKEY-SEE-NO-EVAL;
EVAL "say { 5 + 5 }"; # says 10
```

Symbols in the current lexical scope are visible to code in an `EVAL`

.

```
my $answer = 42;
EVAL 'say $answer;'; # says 42
```

However, since the set of symbols in a lexical scope is immutable after compile time, an EVAL can never introduce symbols into the surrounding scope.

```
EVAL 'my $lives = 9'; say $lives; # error, $lives not declared
```

Furthermore, the `EVAL`

is evaluated in the current package:

```
module M {
EVAL 'our $answer = 42'
}
say $M::answer; # says 42
```

And also the current language, meaning any added syntax is available:

```
sub infix:<mean>(*@a) is assoc<list> {
@a.sum / @a.elems
}
EVAL 'say 2 mean 6 mean 4'; # says 4
```

An `EVAL`

statement evaluates to the result of the last statement:

```
sub infix:<mean>(*@a) is assoc<list> {
@a.sum / @a.elems
}
say EVAL 'say 1; 2 mean 6 mean 4'; # says 1, then says 4
```

`EVAL`

is also a gateway for executing code in other languages:

```
EVAL "use v5.20; say 'Hello from perl5!'", :lang<Perl5>;
```

## (Cool) routine EVALFILE

Defined as:

```
sub EVALFILE(Cool $filename, :$lang = { ... })
```

Slurps the specified file and evaluates it. Behaves the same way as `EVAL`

with regard to both scoping and the `$lang`

parameter. Evaluates to the value produced by the final statement in the file.

```
EVALFILE "foo.p6";
```

# Routines supplied by class Any

FatRat inherits from class Any, which provides the following methods:

## (Any) method ACCEPTS

Defined as:

```
multi method ACCEPTS(Any:D: Mu $other)
```

Usage:

```
EXPR.ACCEPTS(EXPR);
```

Returns `True`

if `$other === self`

(i.e. it checks object identity).

Many built-in types override this for more specific comparisons

## (Any) method any

Defined as:

```
method any() returns Junction:D
```

Interprets the invocant as a list and creates an `any`

-Junction from it.

```
say so 2 == <1 2 3>.any; # True
say so 5 == <1 2 3>.any; # False
```

## (Any) method all

Defined as:

```
method all() returns Junction:D
```

Interprets the invocant as a list and creates an `all`

-Junction from it.

```
say so 1 < <2 3 4>.all; # True
say so 3 < <2 3 4>.all; # False
```

## (Any) method one

Defined as:

```
method one() returns Junction:D
```

Interprets the invocant as a list and creates a `one`

-Junction from it.

```
say so 1 == (1, 2, 3).one; # True
say so 1 == (1, 2, 1).one; # False
```

## (Any) method none

Defined as:

```
method none() returns Junction:D
```

Interprets the invocant as a list and creates a `none`

-Junction from it.

```
say so 1 == (1, 2, 3).none; # False
say so 4 == (1, 2, 3).none; # True
```

## (Any) method list

Interprets the invocant as a list, and returns that List.

```
say 42.list.^name; # List
say 42.list.elems; # 1
```

## (Any) method push

The method push is defined for undefined invocants and allows for autovivifying undefined to an empty `Array`

, unless the undefined value implements `Positional`

already. The argument provided will then be pushed into the newly created Array.

```
my %h;
dd %h<a>; # Any (and therefor undefined)
%h<a>.push(1); # .push on Any
dd %h; # «Hash %h = {:a($[1])}» # please note the Array
```

## (Any) routine reverse

Defined as:

```
multi sub reverse(*@list ) returns List:D
multi method reverse(List:D:) returns List:D
```

Returns a list with the same elements in reverse order.

Note that `reverse`

always refers to reversing elements of a list; to reverse the characters in a string, use flip.

Examples:

```
say <hello world!>.reverse; # (world! hello)
say reverse ^10; # (9 8 7 6 5 4 3 2 1 0)
```

## (Any) method sort

Sorts iterables with `infix:<cmp>`

or given code object and returns a new `List`

.

Examples:

```
say <b c a>.sort; # (a b c)
say 'bca'.comb.sort.join; # abc
say 'bca'.comb.sort({$^b cmp $^a}).join; # cba
say '231'.comb.sort(&infix:«<=>»).join; # 123
```

## (Any) method map

Defined as:

```
proto method map(|) is nodal { * }
```

```
multi method map(\SELF: █; :$label, :$item)
multi method map(HyperIterable:D: █; :$label)
```

`map`

will iterate over the invocant and apply the number of positional parameters of the code object from the invocant per call. The returned values of the code object will become elements of the returned `Seq`

.

## (Any) method deepmap

Defined as:

```
method deepmap(&block -->List) is nodal
```

`deepmap`

will apply `&block`

to each element and return a new `List`

with the return values of `&block`

, unless the element does the `Iterable`

role. For those elements `deepmap`

will descend recursively into the sublist.

```
dd [[1,2,3],[[4,5],6,7]].deepmap(*+1);
# OUTPUT«[[2, 3, 4], [[5, 6], 7, 8]]»
```

## (Any) method duckmap

Defined as:

```
method duckmap(&block) is rw is nodal
```

`duckmap`

will apply `&block`

on each element and return a new list with defined return values of the block. For undefined return values, `duckmap`

will try to descend into the element if that element implements `Iterable`

.

```
my @a = [1,[2,3],4];
dd @a.duckmap({ $_ ~~ Int ?? $_++ !! Any });
# OUTPUT«(1, (2, 3), 4)»
```

## (Any) method flat

Interprets the invocant as a list, flattens it, and returns that list. Please note that `.flat`

will not solve the halting problem for you. If you flat an infinite list `.flat`

may return that infinite list, eating all your RAM in the process.

```
say ((1, 2), (3)).elems; # 2
say ((1, 2), (3)).flat.elems; # 3
```

Please not that `flat`

is not recursing into sub lists. You have to recurse by hand or reconsider your data structures. A single level of nesting can often be handled with destructuring in signatures. For deeper structures you may consider gather/take to create a lazy list.

```
my @a = [[1,2,3],[[4,5],6,7]];
sub deepflat(@a){
gather for @a {
take ($_ ~~ Iterable ?? deepflat($_).Slip !! $_)
}
};
dd deepflat(@a);
# OUTPUT«(1, 2, 3, 4, 5, 6, 7).Seq»
```

## (Any) method eager

Interprets the invocant as a list, evaluates it eagerly, and returns that list.

```
say (1..10).eager; # (1 2 3 4 5 6 7 8 9 10)
```

## (Any) method elems

Interprets the invocant as a list, and returns the number of elements in the list.

```
say 42.elems; # 1
say <a b c>.elems; # 3
```

## (Any) method end

Interprets the invocant as a list, and returns the last index of that list.

```
say 6.end; # 0
say <a b c>.end; # 2
```

## (Any) method pairup

```
method pairup() returns List
```

Interprets the invocant as a list, and constructs a list of pairs from it, in the same way that assignment to a Hash does. That is, it takes two consecutive elements and constructs a pair from them, unless the item in the key position already is a pair (in which case the pair is passed is passed through, and the next list item, if any, is considered to be a key again).

```
say (a => 1, 'b', 'c').pairup.perl; # (:a(1), :b("c")).Seq
```

## (Any) sub exit

```
sub exit(Int() $status = 0)
```

Exits the current process with return code `$status`

.

# Routines supplied by class Mu

FatRat inherits from class Mu, which provides the following methods:

## (Mu) routine defined

```
multi sub defined(Mu) returns Bool:D
multi method defined() returns Bool:D
```

Returns `False`

on the type object, and `True`

otherwise.

```
say Int.defined; # False
say 42.defined; # True
```

Very few types (like Failure) override `defined`

to return `False`

even for instances:

```
sub fails() { fail 'oh noe' };
say fails().defined; # False
```

## (Mu) routine isa

```
multi method isa(Mu $type) returns Bool:D
multi method isa(Str:D $type) returns Bool:D
```

Returns `True`

if the invocant is an instance of class `$type`

, a subset type or a derived class (through inheritance) of `$type`

.

```
my $i = 17;
say $i.isa("Int"); # True
say $i.isa(Any); # True
```

A more idiomatic way to do this is to use the smartmatch operator ~~ instead.

```
my $s = "String";
say $s ~~ Str; # True
```

## (Mu) routine does

```
method does(Mu $type) returns Bool:D
```

Returns `True`

if and only if the invocant conforms to type `$type`

.

```
my $d = Date.new('2016-06-03');
say $d.does(Dateish); # True (Date does role Dateish)
say $d.does(Any); # True (Date is a subclass of Any)
say $d.does(DateTime); # False (Date is not a subclass of DateTime)
```

Using the smart match operator ~~ is a more idiomatic alternative.

```
my $d = Date.new('2016-06-03');
say $d ~~ Dateish; # True
say $d ~~ Any; # True
say $d ~~ DateTime; # False
```

## (Mu) routine Bool

```
multi sub Bool(Mu) returns Bool:D
multi method Bool() returns Bool:D
```

Returns `False`

on the type object, and `True`

otherwise.

Many built-in types override this to be `False`

for empty collections, the empty string or numerical zeros

```
say Mu.Bool; # False
say Mu.new.Bool; # True
say [1, 2, 3].Bool; # True
say [].Bool; # False
say { 'hash' => 'full'}.Bool; # True
say {}.Bool; # False
```

## (Mu) method Str

```
multi method Str() returns Str
```

Returns a string representation of the invocant, intended to be machine readable. Method `Str`

warns on type objects, and produces the empty string.

```
say Mu.Str; #!> use of uninitialized value of type Mu in string context
```

## (Mu) routine gist

```
multi sub gist(Mu) returns Str
multi method gist() returns Str
```

Returns a string representation of the invocant, optimized for fast recognition by humans. As such lists will be truncated at 100 elements. Use `.perl`

to get all elements.

The default `gist`

method in `Mu`

re-dispatches to the perl method for defined invocants, and returns the type name in parenthesis for type object invocants. Many built-in classes override the case of instances to something more specific that may truncate output.

`gist`

is the method that say calls implicitly, so `say $something`

and `say $something.gist`

generally produce the same output.

```
say Mu.gist; # (Mu)
say Mu.new.gist; # Mu.new
```

## (Mu) routine perl

```
multi sub perl(Mu) returns Str
multi method perl() returns Str
```

Returns a Perlish representation of the object (i.e., can usually be re-evaluated with EVAL to regenerate the object). The exact output of `perl`

is implementation specific, since there are generally many ways to write a Perl expression that produces a particular value

## (Mu) method clone

```
method clone(*%twiddles)
```

Creates a shallow clone of the invocant. If named arguments are passed to it, their values are used in every place where an attribute name matches the name of a named argument.

```
class Point2D {
has ($.x, $.y);
multi method gist(Point2D:D:) {
"Point($.x, $.y)";
}
}
my $p = Point2D.new(x => 2, y => 3);
say $p; # Point(2, 3)
say $p.clone(y => -5); # Point(2, -5)
```

## (Mu) method new

```
multi method new(*%attrinit)
```

Default method for constructing (create + initialize) new objects of a class. This method expects only named arguments which are then used to initialize attributes with accessors of the same name.

Classes may provide their own `new`

method to override this default.

`new`

triggers an object construction mechanism that calls submethods named `BUILD`

in each class of an inheritance hierarchy, if they exist. See the documentation on object construction for more information.

## (Mu) method bless

```
method bless(*%attrinit) returns Mu:D
```

Lower-level object construction method than `new`

.

Creates a new object of the same type as the invocant, uses the named arguments to initialize attributes, and returns the created object.

You can use this method when writing custom constructors:

```
class Point {
has $.x;
has $.y;
multi method new($x, $y) {
self.bless(:$x, :$y);
}
}
my $p = Point.new(-1, 1);
```

(Though each time you write a custom constructor, remember that it makes subclassing harder).

## (Mu) method CREATE

```
method CREATE() returns Mu:D
```

Allocates a new object of the same type as the invocant, without initializing any attributes.

```
say Mu.CREATE.defined; # True
```

## (Mu) method print

```
multi method print() returns Bool:D
```

Prints value to `$*OUT`

after stringification using `.Str`

method without adding a newline at end.

```
"abc\n".print; # abc
```

## (Mu) method put

```
multi method put() returns Bool:D
```

Prints value to `$*OUT`

after stringification using `.Str`

method adding a newline at end.

```
"abc".put; # abc
```

## (Mu) method say

```
multi method say() returns Bool:D
```

Prints value to `$*OUT`

after stringification using `.gist`

method with newline at end. To produce machine readable output use `.put`

.

```
say 42; # 42
```

## (Mu) method ACCEPTS

```
multi method ACCEPTS(Mu:U: $other)
```

`ACCEPTS`

is the method that smart matching with the infix ~~ operator and given/when invokes on the right-hand side (the matcher).

The `Mu:U`

multi performs a type check. Returns `True`

if `$other`

conforms to the invocant (which is always a type object or failure).

```
say 42 ~~ Mu; # True
say 42 ~~ Int; # True
say 42 ~~ Str; # False
```

Note that there is no multi for defined invocants; this is to allow autothreading of junctions, which happens as a fallback mechanism when no direct candidate is available to dispatch to.

## (Mu) method WHICH

```
multi method WHICH() returns ObjAt:D
```

Returns an object of type ObjAt which uniquely identifies the object. Value types override this method which makes sure that two equivalent objects return the same return value from `WHICH`

.

```
say 42.WHICH eq 42.WHICH; # True
```

## (Mu) method WHERE

```
method WHERE() returns Int
```

Returns an `Int`

representing the memory address of the object.

## (Mu) method WHY

```
multi method WHY()
```

Returns the attached Pod value. For instance,

```
sub cast(Spell $s)
#= Initiate a specified spell normally
#= (do not use for class 7 spells)
{
do-raw-magic($s);
}
say &cast.WHY;
```

prints

```
Initiate a specified spell normally (do not use for class 7 spells)
```

See the documentation specification for details about attaching Pod to variables, classes, functions, methods, etc.

## (Mu) trait is export

```
multi sub trait_mod:<is>(Mu:U \type, :$export!)
```

Marks a type as being exported, that is, available to external users.

```
my class SomeClass is export { }
```

A user of a module or class automatically gets all the symbols imported that are marked as `is export`

.

See Exporting and Selective Importing Modules for more details.

## (Mu) method return

```
method return()
```

The method `return`

will stop execution of a subroutine or method, run all relevant phasers and provide invocant as a return value to the caller. If a return type constraint is provided it will be checked unless the return value is `Nil`

. A control exception is raised and can be caught with CONTROL.

```
sub f { (1|2|3).return };
dd f(); # OUTPUT«any(1, 2, 3)»
```

## (Mu) method return-rw

Same as method `return`

except that `return-rw`

returns a writeable container to the invocant (see more details here: `return-rw`

).

## (Mu) method take

```
method take()
```

Takes the given item and passes it to the enclosing `gather`

block.

```
#| randomly select numbers for lotto
my $num-selected-numbers = 6;
my $max-lotto-numbers = 49;
gather for ^$num-selected-numbers {
take (1 .. $max-lotto-numbers).pick(1);
}.say; #-> 32 22 1 17 32 9 (for example)
```

## (Mu) method so

```
method so()
```

Returns a `Bool`

value representing the logical non-negation of an expression. One can use this method similarly to the English sentence: "If that is **so**, then do this thing". For instance,

```
my @args = <-a -e -b -v>;
my $verbose-selected = any(@args) eq '-v' | '-V';
if $verbose-selected.so {
say "Verbose option detected in arguments";
} #-> Verbose option detected in arguments
```

## (Mu) method not

```
method not()
```

Returns a `Bool`

value representing the logical negation of an expression. Thus it is the opposite of `so`

.

```
my @args = <-a -e -b>;
my $verbose-selected = any(@args) eq '-v' | '-V';
if $verbose-selected.not {
say "Verbose option not present in arguments";
} #-> Verbose option not present in arguments
```

Since there is also a prefix version of `not`

, the above code reads better like so:

```
my @args = <-a -e -b>;
my $verbose-selected = any(@args) eq '-v' | '-V';
if not $verbose-selected {
say "Verbose option not present in arguments";
} #-> Verbose option not present in arguments
```