Variables are symbolic names for values or containers. Variable declarations or assignment of values may create a container on the fly. Variable names can start with or without a special character called a sigil, followed optionally by a second special character named twigil and then an identifier.

§

There are four sigils. The scalar-sigil $, the positional-sigil @, the associative-sigil % and the callable-sigil &.

Sigils provide a link between syntax, the type system and containers. They provide a shortcut for the most common type constraints when declaring variables, and serve as markers for string interpolation. The positional-sigil and the associative-sigil provide type constraint that enforce base type subscripts required to know what methods to dispatch to. The callable-sigil does the same for function calls. The latter also tells the compiler where parentheses for calls can be omitted. The positional and associative-sigil also simplify assignment by flattening by default.

Examples:

my $square = 9 ** 2;
my @array  = 1, 2, 3;   # Array variable with three elements 
my %hash   = London => 'UK', Berlin => 'Germany';

The type to which the variable will be bound can be set with is in the declaration of the variable. Assuming we have a FailHash class:

class FailHash is Hash {
    has Bool $!final = False;
    multi method AT-KEY ( ::?CLASS:D: Str:D \key ){
        fail X::OutOfRange.new(:what("Hash key"), :got(key),
          :range(self.keys)) if $!final && !self.EXISTS-KEY(key);
        callsame  # still not final, so do normal action from Hash 
    }
 
    method finalize() {
        $!final = True
    }
}

One can then define a %h variable of this type using is:

my %h is FailHash = oranges => "round", bananas => "bendy";

And then run the following code:

say %h<oranges>;
# OUTPUT: «round␤» 
%h.finalize;
say %h<cherry>;
CATCH { default { put .^name, ': ', .Str } }
# OUTPUT: «X::OutOfRange: Hash key out of range. Is: cherry, should be in (oranges bananas)» 

For information on variables without sigils, see sigilless variables.

Item and list assignment§

There are two types of variable assignment, item assignment and list assignment.

An item assignment copies a single value from the right-hand side into a Scalar variable on the left. An assignment to anything other than a simple Scalar variable is parsed as a list assignment. A list assignment leaves the choice of what the assignment operation entails to the variable on the left. For example, Array variables (@ sigil) empty themselves on list assignment, and then iteratively copy all values from the right-hand side into themselves as elements.

The two types of assignment both use the equal sign = as their operator and are both right associative, but differ in operator precedence: item assignment has a higher precedence level (level: Item assignment) than list assignment (level: List prefix). In situations in which a comma-separated list of elements is assigned, these precedences should in particular be contrasted with that of the comma operator , which sits in between. So without any list-delimiting parentheses (or other construct to hold the list's elements together), item assignment will only assign the first element of the specified list, and not the full list.

In an assignment expression the context of the left-hand side determines whether an = means item or list assignment. As mentioned, item assignment is restricted to simple Scalar variables. Accordingly, assignment to a Scalar container (scalar-context) triggers item assignment, unless the Scalar is explicitly put in list-context by surrounding parentheses ( ):

my $a;
$a = 1,2,3;        # item assignment to Scalar 
say $a;            # OUTPUT: «1␤» ( '=' has higher precedence than ',' ) 
 
my $b = 1,2,3;     # item assignment to Scalar (same as preceding example) 
say $b;            # OUTPUT: «1␤» 
 
my $c;
($c) = 4,5,6;      # list assignment to Scalar; '( )' is list-contextualizer 
say $c;            # OUTPUT:  «(4,5,6)␤» 
 
(my $d) = 4,5,6;   # list assignment to Scalar (same as preceding example) 
say $d;            # OUTPUT:  «(4,5,6)␤»

Assignment to a List container (list-context) always triggers list assignment:

my @e;
@e = 7,8,9;                    # list assignment to Array 
say @e;                        # OUTPUT:  «[7,8,9]␤» 
 
my $f;
($f,) = 7,8,9;                 # list assignment to List with one element 
say $f;                        # OUTPUT:  «7␤» 
say ( ($f,) ).VAR.^name;       # OUTPUT:  «List␤» 
 
# ATTENTION: special declaration syntax! 
my ($g) = 7,8,9;               # list assignment to List with one element 
say $g;                        # OUTPUT:  «7␤» 
say ( ($g) ).VAR.^name         # OUTPUT:  «List␤»

The last two examples above are simple destructuring assignments that select the first item of the right-hand side list. See for a more elaborate discussion of destructuring assignments in the context of variable declarations the section on declaring a list of variables with lexical or package scope.

Chained assignments are parsed having regard to the precedence of the assignment operators and, where applicable, their right associativity. For instance, in the example below there is one chained assignment statement comprising two assignment operators. The assignment to @array is a list assignment having a lower precedence than the item assignment to the Scalar variable $num. The assignment expression involving the item assignment to the Scalar variable $num is thus evaluated first. It returns the assigned value 42, which in turn forms part of the List (42, "str") constructed by the comma operator that also has a higher precedence than the list assignment. Finally, the List (42, "str") is list-assigned to @array:

my @array;
@array = my $num = 42, "str";   # parsed as @array = ( (my $num = 42), "str ) 
say @array.raku;                # OUTPUT: «[42, "str"]␤» (an Array) 
say $num.raku;                  # OUTPUT: «42␤» (a Num)

Here's a variant:

my ( @foo, $bar );
@foo = ($bar) = 42, "str";       # parsed as @foo = ( $bar = (42, "str") ) 
say $bar.raku;                   # OUTPUT: «$(42, "str")␤» (a List)# 
say @foo.raku;                   # OUTPUT: «[(42, "str"),]␤» (an Array)

In this case, the list contextualizer ( ) puts $bar in a list context, and thus triggers a list assignment to the Scalar variable $bar. This means that there are two chained list assignments, both having a lower precedence than the comma operator , that constructs the List (42, "str"). Due to their right associativity, the list assignment expression that is evaluated first is the assignment to $bar, which returns the assigned value $(42, "str"), i.e. a Scalar containing a two-element List. This value is in turn list-assigned to @array, such that it becomes an Array with a single element, namely a List.

See operators for more details on precedence and associativity.

Sigilless variables §

Using the \ prefix, it's possible to create variables that do not have a sigil:

my \degrees = pi / 180;
my \θ       = 15 * degrees;

Note that sigilless variable do not have associated containers. This means degrees and θ, above, actually directly represent Nums. To illustrate, try assigning to one after you've defined it:

θ = 3; # Dies with the error "Cannot modify an immutable Num" 

Sigilless variables do not enforce context, so they can be used to pass something on as-is:

sub logged(&f, |args) {
    say('Calling ' ~ &f.name ~ ' with arguments ' ~ args.raku);
    my \result = f(|args);
    #  ^^^^^^^ not enforcing any context here 
    say(&f.name ~ ' returned ' ~ result.raku);
    return |result;
}

Sigilless variables can also be used for binding. See Binding for more information.

Twigils§

We use the term twigils, a word play with sigil, that indicates it uses two symbols in front of an identifier; the second symbol will be placed between the sigil and the identifier, and it will be related to the scoping of a variable, that is, where that variable is defined and can be changed.

§

This twigil is used for dynamic variables which are looked up through the caller's, not through the outer, scope. Look at the example below.^[1]

my $lexical   = 1;
my $*dynamic1 = 10;
my $*dynamic2 = 100;
 
sub say-all() {
    say "$lexical, $*dynamic1, $*dynamic2";
}
 
say-all();    # OUTPUT: 1, 10, 100 
 
{
    my $lexical   = 2;
    my $*dynamic1 = 11;
    $*dynamic2    = 101;
 
    say-all(); # OUTPUT: 1, 11, 101 
}
 
say-all();  # OUTPUT: 1, 10, 101 

The first time &say-all is called, it prints "1, 10, 100" just as one would expect. The second time though, it prints "1, 11, 101". This is because $lexical isn't looked up in the caller's scope but in the scope &say-all was defined in. The two dynamic variables are looked up in the caller's scope and therefore have the values 11 and 101. The third time &say-all is called $*dynamic1 isn't 11 anymore, but $*dynamic2 is still 101. This stems from the fact that we declared a new dynamic variable $*dynamic1 in the block and did not assign to the old variable as we did with $*dynamic2.

The dynamic variables differ from other variable types in that referring to an undeclared dynamic variable is not a compile time error but a runtime Failure, so a dynamic variable can be used undeclared as long as it's checked for definedness or used in a Boolean context before using it for anything else:

sub foo() {
    $*FOO // 'foo';
}
 
say foo; # OUTPUT: «foo␤» 
 
my $*FOO = 'bar';
 
say foo; # OUTPUT: «bar␤» 

Dynamic variables can have lexical scope when declared with my or package scope when declared with our. Dynamic resolution and resolution through symbol tables introduced with our are two orthogonal issues.

§

Compile-time variables may be addressed via the ? twigil. They are known to the compiler and may not be modified after being compiled in. A popular example for this is:

say "$?FILE: $?LINE"; # OUTPUT: "hello.raku: 23" 
                      # if this is the line 23 of a 
                      # file named "hello.raku"

For a list of these special variables, see compile-time variables.

§

Attributes are variables that exist per instance of a class. They may be directly accessed from within the class via !:

my class Point {
    has $.x;
    has $.y;
 
    method Str() {
        "($!x, $!y)"
    }
}

Note how the attributes are declared as $.x and $.y but are still accessed via $!x and $!y. This is because in Raku all attributes are private and can be directly accessed within the class by using $!attribute-name. Raku may automatically generate accessor methods for you though. For more details on objects, classes and their attributes see object orientation.

§

The . twigil isn't really for variables at all. In fact, something along the lines of

my class Point {
    has $.x;
    has $.y;
 
    method Str() {
        "($.x, $.y)" # note that we use the . instead of ! this time 
    }
}

just calls the methods x and y on self, which are automatically generated for you because you used the . twigil when the attributes were declared. Note, however, that subclasses may override those methods. If you don't want this to happen, use $!x and $!y instead.

The fact that the . twigil does a method call implies that the following is also possible:

class SaySomething {
    method a() { say "a"; }
    method b() { $.a; }
}
 
SaySomething.b; # OUTPUT: «a␤»

For more details on objects, classes and their attributes and methods see object orientation.

§

The ^ twigil declares a formal positional parameter to blocks or subroutines; that is, variables of the form $^variable are a type of placeholder variable. They may be used in bare blocks to declare formal parameters to that block. So the block in the code

my @powers-of-three = 1,3,9…100;
say reduce { $^b - $^a }, 0, |@powers-of-three;
# OUTPUT: «61␤»

has two formal parameters, namely $a and $b. Note that even though $^b appears before $^a in the code, $^a is still the first formal parameter to that block. This is because the placeholder variables are sorted in Unicode order.

Although it is possible to use nearly any valid identifier as a placeholder variable, it is recommended to use short names or ones that can be trivially understood in the correct order, to avoid surprise on behalf of the reader.

Normal blocks and subroutines may also make use of placeholder variables but only if they do not have an explicit parameter list.

sub say-it    { say $^a; } # valid 
sub say-it()  { say $^a; } # invalid 
              { say $^a; } # valid 
-> $x, $y, $x { say $^a; } # invalid 

Placeholder variables cannot have type constraints or a variable name with a single uppercase letter (this is disallowed to enable catching some Perl-isms).

The ^ twigil can be combined with any sigil to create a placeholder variable with that sigil. The sigil will have its normal semantic effects, as described in the Sigils table. Thus @^array, %^hash, and &^fun are all valid placeholder variables.

§

The : twigil declares a formal named parameter to a block or subroutine. Variables declared using this form are a type of placeholder variable too. Therefore the same things that apply to variables declared using the ^ twigil also apply here (with the exception that they are not positional and therefore not ordered using Unicode order). For instance:

say { $:add ?? $^a + $^b !! $^a - $^b }( 4, 5 ) :!add
# OUTPUT: «-1␤»

See ^ for more details about placeholder variables.

A note on ^ and :§

Unlike other twigils, ^ and : declare variables, which can then be referred to without that twigil. Thus, the previous example could be written as:

say { $:add ?? $^a + $^b !! $a - $b }( 4, 5 ) :!add      # OUTPUT: «-1␤»

That is, once you have used $^a to declare $a, you can refer to that variable in the same scope with either $^a or $a. The same is true for :: after declaring $:add, you are free to refer to that declared variable with $add if you prefer.

In some instances, this is just a convenience – but it can be much more significant when dealing with nested blocks. For example:

{ say $^a; with "inner" { say $^a } }("outer");       # OUTPUT: «outer␤inner␤» 
{ say $^a; with "inner" { say $a } }("outer");        # OUTPUT: «outer␤outer␤»

The first line declares two formal positional parameters, while the second declares only one (but refers to it twice). This can be especially significant with constructs such as with, for, and if that are often used without much consideration of the fact that they create blocks.

Just like the ^twigil, the : twigil can be combined with any sigil; using : with a sigil will create a formal named parameter with that sigil (applying the semantics of that sigil). Thus @:array, %:hash, and &:fun are all valid, and each creates a formal named parameter with the specified sigil.

§

The = twigil is used to access Pod variables. Every Pod block in the current file can be accessed via a Pod object, such as $=data, $=SYNOPSIS or =UserBlock. That is: a variable with the same name of the desired block and a = twigil.

=begin Foo
...
=end Foo
# after that, $=Foo gives you all Foo-Pod-blocks 

You may access the Pod tree which contains all Pod structures as a hierarchical data structure through $=pod.

Note that all those $=someBlockName support the Positional and the Associative roles.

The ~ twigil §

The ~ twigil is for referring to sublanguages (called slangs). The following are useful:

You augment these languages in your current lexical scope.

use MONKEY-TYPING;
augment slang Regex {  # derive from $~Regex and then modify $~Regex 
    token backslash:std<\Y> { YY };
}

Variable declarators and scope§

Most of the time it's enough to create a new variable using the my keyword:

my $amazing-variable = "World";
say "Hello $amazing-variable!"; # OUTPUT: «Hello World!␤»

However, there are many declarators that change the details of scoping beyond what Twigils can do.

There are also three prefixes that resemble declarators but act on predefined variables:

The my declarator§

Declaring a variable with my gives it lexical scope. This means it only exists within the current block. For example:

{
    my $foo = "bar";
    say $foo; # OUTPUT: «"bar"␤» 
}
say $foo; # Exception! "Variable '$foo' is not declared" 

This dies because $foo is only defined as long as we are in the same scope.

In order to create more than one variable with a lexical scope in the same sentence surround the variables with parentheses:

my ( $foo, $bar );

see also Declaring a list of variables with lexical or package scope.

Additionally, lexical scoping means that variables can be temporarily redefined in a new scope:

my $location = "outside";
 
sub outer-location {
    # Not redefined: 
    say $location;
}
 
outer-location; # OUTPUT: «outside␤» 
 
sub in-building {
    my $location = "inside";
    say $location;
}
 
in-building;    # OUTPUT: «inside␤» 
 
outer-location; # OUTPUT: «outside␤»

If a variable has been redefined, any code that referenced the outer variable will continue to reference the outer variable. So here, &outer-location still prints the outer $location:

sub new-location {
    my $location = "nowhere";
    outer-location;
}
 
new-location; # OUTPUT: «outside␤» 

To make new-location() print nowhere, make $location a dynamic variable using the * twigil. This twigil makes the compiler look up the symbol in the calling scope instead of the outer scope after trying the local scope.

my is the default scope for subroutines, so my sub x() {} and sub x() {} do exactly the same thing.

The our declarator§

our variables are created in the scope of the surrounding package. They also create an alias in the lexical scope, therefore they can be used like my variables as well.

module M {
    our $Var;
    # $Var available here 
}
 
# Available as $M::Var here.

In order to create more than one variable with package scope, at the same time, surround the variables with parentheses:

our ( $foo, $bar );

see also the section on declaring a list of variables with lexical or package scope.

Declaring a list of variables with lexical (my) or package (our) scope§

It is possible to scope more than one variable at a time, but both my and our require variables to be placed into parentheses:

my  (@a,  $s,  %h);   # same as my @a; my $s; my %h; 
our (@aa, $ss, %hh);  # same as our @aa; our $ss; our %hh;

This can be used in conjunction with destructuring assignment. Any assignment to such a list will take the number of elements provided in the left list and assign corresponding values from the right list to them. Any missing elements are left will result in undefined values according to the type of the variables.

my (Str $a, Str $b, Int $c) = <a b>;
say [$a, $b, $c].raku;
# OUTPUT: «["a", "b", Int]␤»

To destructure a list into a single value, create a list literal with one element by using ($var,). When used with a variable declarator, providing parentheses around a single variable is sufficient.

sub f { 1,2,3 };
my ($a) = f;
say $a.raku;
# OUTPUT: «1␤»

To skip elements in the list use the anonymous state variable $.

my ($,$a,$,%h) = ('a', 'b', [1,2,3], {:1th});
say [$a, %h].raku;
# OUTPUT: «["b", {:th(1)}]␤»

The has declarator§

has scopes attributes to instances of a class or role, and methods to classes or roles. has is implied for methods, so has method x() {} and method x() {} do the same thing.

See object orientation for more documentation and some examples.

The anon declarator§

The anon declarator prevents a symbol from getting installed in the lexical scope, the method table and everywhere else.

For example, you can use it to declare subroutines which know their own name, but still aren't installed in a scope:

my %operations =
    half   => anon sub half($x) { $x / 2 },
    square => anon sub square($x) { $x * $x },
    ;
say %operations<square>.name;       # square 
say %operations<square>(8);         # 64

Since it is a declarator, it can be applied anywhere anything is declared, for instance for classes or even sigilless variables.

say anon class þ {};     # OUTPUT: «(þ)␤» 
say anon sub þ  { 42 };  # OUTPUT: «&þ␤»

Since these symbols are not installed in the scope, they can't be used by name. They are useful, however, if they need to be assigned to an external variable and they need to know their own name, but this can be retrieved using introspection.

my $anon-class = anon class {
    has $.bar;
    method equal( ::?CLASS $foo ) {
      return $foo.bar == $.bar;
    }
};
say $anon-class.new( :3bar).equal( $anon-class.new( :3bar ) );
# OUTPUT: «True␤» 

The state declarator§

state declares lexically scoped variables, just like my. However, initialization happens exactly once, the first time the initialization is encountered in the normal flow of execution. Thus, state variables will retain their value across multiple executions of the enclosing block or routine.

Therefore, the subroutine

sub a {
    state @x;
    state $l = 'A';
    @x.push($l++);
};
 
say a for 1..6;

will continue to increment $l and append it to @x each time it is called. So it will output:

[A]
[A B]
[A B C]
[A B C D]
[A B C D E]
[A B C D E F]

Since they have a lexical scope, they are tied to the block in which they are declared.

sub foo () {
  for 0..1 {
    state $foo = 1;
    say $foo++;
  }
};
foo;  # OUTPUT: «1␤2␤» 
foo;  # OUTPUT: «1␤2␤» 

In this case, a new state variable is created every time the block that runs the for loop is entered, which is why the state variable is reset in every call to foo.

This works per "clone" of the containing code object, as in this example:

({ state $i = 1; $i++.say; } xx 3).map: {$_(), $_()}; # OUTPUT: «1␤2␤1␤2␤1␤2␤» 

Note that this is not a thread-safe construct when the same clone of the same block is run by multiple threads. Also remember that methods only have one clone per class, not per object.

As with my, a declaration of multiple state variables must be placed in parentheses which can be omitted for a single variable.

Many operators come with implicit binding which can lead to actions at a distance.

Use .clone or coercion to create a new container that can be bound to.

my @a;
my @a-cloned;
sub f() {
    state $i;
    $i++;
    @a       .push: "k$i" => $i;
    @a-cloned.push: "k$i" => $i.clone;
};
 
f for 1..3;
say @a;        # OUTPUT: «[k1 => 3 k2 => 3 k3 => 3]␤» 
say @a-cloned; # OUTPUT: «[k1 => 1 k2 => 2 k3 => 3]␤»

State variables are shared between all threads. The result can be unexpected.

sub code(){ state $i = 0; say ++$i; $i };
await
    start { loop { last if code() >= 5 } },
    start { loop { last if code() >= 5 } };
 
# OUTPUT: «1␤2␤3␤4␤4␤3␤5␤» 
# OUTPUT: «2␤1␤3␤4␤5␤» 
# many other more or less odd variations can be produced

The $ variable§

In addition to explicitly declared named state variables, $ can be used as an anonymous state variable without an explicit state declaration.

say "1-a 2-b 3-c".subst(:g, /\d/, {<one two three>[$++]});
# OUTPUT: «one-a two-b three-c␤»

Furthermore, state variables can be used outside of subroutines. You could, for example, use $ in a one-liner to number the lines in a file.

raku -ne 'say ++$ ~ " $_"' example.txt

Each reference to $ within a lexical scope is in effect a separate variable.

raku -e '{ say ++$; say $++  } for ^5'
# OUTPUT: «1␤0␤2␤1␤3␤2␤4␤3␤5␤4␤»

That is why, if you need to reference the same $ variable (or, for that matter, any of the other anon state variables @ and %) more than once, a possible solution is to bind another variable to it, although in this example it would be more straightforward to just declare state $x and not use the magical/anonymous $ variable:

sub foo () {
    my $x := $;
    $x++;
    say $x;
    $x = $x + 1;
}
 
foo() for ^3; # OUTPUT: «1␤3␤5␤» 

In general, it is better style to declare a named state variable in case you have to refer to it several times.

Note that the implicit state declarator is only applied to the variable itself, not the expression that may contain an initializer. If the initializer has to be called exactly once, the state declarator has to be provided.

for ^3 {       $ = .say } # OUTPUT: «0␤1␤2␤» 
for ^3 { state $ = .say } # OUTPUT: «0␤» 

The @ variable§

Similar to the $ variable, there is also a Positional anonymous state variable @.

sub foo($x) {
    say (@).push($x);
}
 
foo($_) for ^3;
 
# OUTPUT: «[0] 
#          [0 1] 
#          [0 1 2]␤»

The @ here is parenthesized in order to disambiguate the expression from a class member variable named @.push. Indexed access doesn't require this disambiguation but you will need to copy the value in order to do anything useful with it.

sub foo($x) {
    my $v = @;
    $v[$x] = $x;
    say $v;
}
 
foo($_) for ^3;
 
# OUTPUT: «[0] 
#          [0 1] 
#          [0 1 2]␤»

As with $, each mention of @ in a scope introduces a new anonymous array.

The % variable§

In addition, there's an Associative anonymous state variable %.

sub foo($x) {
    say (%).push($x => $x);
}
 
foo($_) for ^3;
 
# OUTPUT: «{0 => 0} 
#          {0 => 0, 1 => 1} 
#          {0 => 0, 1 => 1, 2 => 2}␤»

The same caveat about disambiguation applies. As you may expect, indexed access is also possible (with copying to make it useful).

sub foo($x) {
    my $v = %;
    $v{$x} = $x;
    say $v;
}
 
foo($_) for ^3;
 
# OUTPUT: «{0 => 0} 
#          {0 => 0, 1 => 1} 
#          {0 => 0, 1 => 1, 2 => 2}␤»

As with the other anonymous state variables, each mention of % within a given scope will effectively introduce a separate variable.

The augment declarator§

With augment, you can add methods, but not attributes, to existing classes and grammars, provided you activated the MONKEY-TYPING pragma first.

Since classes are usually our scoped, and thus global, this means modifying global state, which is strongly discouraged. For almost all situations, there are better solutions.

# don't do this 
use MONKEY-TYPING;
augment class Int {
    method is-answer { self == 42 }
}
say 42.is-answer;       # OUTPUT: «True␤»

(In this case, the better solution would be to use a function).

For a better, and safer example, this is a practical way to create a class module to extend IO::Path by adding a currently missing method to yield the part of the basename left after the extension is removed. (Note there is no clear developer consensus about what to call that part or even how it should be constructed.)

unit class IO::Barename is IO::Path;
 
method new(|c) {
    return self.IO::Path::new(|c);
}
 
use MONKEY-TYPING;
augment class IO::Path {
    method barename {
        self.extension("").basename;
    }
}

The temp prefix§

Like my, temp restores the old value of a variable at the end of its scope. However, temp does not create a new variable.

my $in = 0; # temp will "entangle" the global variable with the call stack 
            # that keeps the calls at the bottom in order. 
sub f(*@c) {
    (temp $in)++;
     "<f>\n"
     ~ @c».indent($in).join("\n")
     ~ (+@c ?? "\n" !! "")
     ~ '</f>'
};
sub g(*@c) {
    (temp $in)++;
    "<g>\n"
    ~ @c».indent($in).join("\n")
    ~ (+@c ?? "\n" !! "")
    ~ "</g>"
};
print g(g(f(g()), g(), f()));
 
# OUTPUT: «<g> 
#           <g> 
#            <f> 
#             <g> 
#             </g> 
#            </f> 
#            <g> 
#            </g> 
#            <f> 
#            </f> 
#           </g> 
#          </g>␤»

The let prefix§

Restores the previous value if the block exits unsuccessfully. A successful exit means the block returned a defined value or a list.

my $answer = 42;
 
{
    let $answer = 84;
    die if not Bool.pick;
    CATCH {
        default { say "it's been reset :(" }
    }
    say "we made it 84 sticks!";
}
 
say $answer;

In the above case, if the Bool.pick returns true, the answer will stay as 84 because the block returns a defined value (say returns True). Otherwise the die statement will cause the block to exit unsuccessfully, resetting the answer to 42.

The constant prefix§

The constant prefix declares that the value it tags is not going to change during its lifetime.

constant $pi2 = pi * 2;
$pi2 = 6; # OUTPUT: «(exit code 1) Cannot assign to an immutable value␤ 

The value is assigned at compile time. Since Raku modules are precompiled automatically, constants defined in modules are not re-evaluated when the program is run. Please check the section on constants in the Terms page for additional information.

Type constraints and initialization§

Variables have a type constraint via the container they are bound to, which goes between the declarator and the variable name. The default type constraint is Mu. You can also use the trait of to set a type constraint.

    my Int $x = 42;
    $x = 'a string';
    CATCH { default { put .^name, ': ', .Str } }
    # OUTPUT: «X::TypeCheck::Assignment: Type check failed in assignment to $x; 
    expected Int but got Str ("a string")␤»

If a scalar variable has a type constraint but no initial value, it's initialized with the type object of the default value of the container it's bound to.

my Int $x;
say $x.^name;       # OUTPUT: «Int␤» 
say $x.defined;     # OUTPUT: «False␤»

Scalar variables without an explicit type constraint are typed as Mu but default to the Any type object.

Variables with the @ sigil are initialized with an empty Array; variables with the % sigil are initialized with an empty Hash.

The default value of a variable can be set with the is default trait, and re-applied by assigning Nil to it:

my Real $product is default(1);
say $product;                       # OUTPUT: «1␤» 
$product *= 5;
say $product;                       # OUTPUT: «5␤» 
$product = Nil;
say $product;                       # OUTPUT: «1␤»

Default defined variables pragma§

To force all variables to have a definiteness constraint, use the pragma use variables :D. The pragma is lexically scoped and can be switched off with use variables :_.

use variables :D;
my Int $i;
# OUTPUT: «===SORRY!=== Error while compiling <tmp>␤Variable definition of type Int:D (implicit :D by pragma) requires an initializer ... 
my Int $i = 1; # that works 
{ use variables :_; my Int $i; } # switch it off in this block 

Note that assigning Nil will revert the variable to its default value, which is often not a definite value and as such would fail the constraint:

use variables :D;
my Int $x = 42;
$x = Nil;
# OUTPUT: «Type check failed in assignment to $x; expected type Int:D cannot be itself…» 

As the name suggests, this pragma applies only to variables.

Special variables§

Raku attempts to use long, descriptive names for special variables. There are only three special variables that are extra short.

Pre-defined lexical variables§

There are four special variables that are always available:

Note that while you can access $¢ without error anywhere, it will contain Nil if accessed outside of a regex.

The $_ variable§

$_ is the topic variable. A fresh one is created in every block. It's also the default parameter for blocks that do not have an explicit signature, so constructs like for @array { ... } and given $var { ... } bind the value or values of the variable to $_ by invoking the block.

for <a b c> { say $_ }  # binds $_ to 'a', 'b' and 'c' in turn 
say $_ for <a b c>;     # same, even though it's not a block 
given 'a'   { say $_ }  # binds $_ to 'a' 
say $_ given 'a';       # same, even though it's not a block

Because $_ is bound to the value of the iteration, you can also assign to $_ if it is bound to something assignable.

my @numbers = ^5;   # 0 through 4 
$_++ for @numbers;  # increment all elements of @numbers 
say @numbers;
 
# OUTPUT: «1 2 3 4 5␤»

CATCH blocks bind $_ to the exception that was caught. The ~~ smartmatch operator binds $_ on the right-hand side expression to the value of the left-hand side.

Calling a method on $_ can be shortened by leaving off the variable name:

.say;                   # same as $_.say

m/regex/ and /regex/ regex matches and s/regex/subst/ substitutions work on $_:

say "Looking for strings with non-alphabetic characters...";
for <ab:c d$e fgh ij*> {
    .say if m/<-alpha>/;
}
 
# OUTPUT: «Looking for strings with non-alphabetic characters... 
#          ab:c 
#          d$e 
#          ij*␤»

The $/ variable§

$/ is the match variable. A fresh one is created in every routine. It is set to the result of the last Regex match and so usually contains objects of type Match.

'abc 12' ~~ /\w+/;  # sets $/ to a Match object 
say $/.Str;         # OUTPUT: «abc␤»

The Grammar.parse method also sets the caller's $/ to the resulting Match object. For the following code:

use XML::Grammar; # zef install XML 
XML::Grammar.parse("<p>some text</p>");
say $/;
 
# OUTPUT: «｢<p>some text</p>｣ 
#           root => ｢<p>some text</p>｣ 
#            name => ｢p｣ 
#            child => ｢some text｣ 
#             text => ｢some text｣ 
#             textnode => ｢some text｣ 
#           element => ｢<p>some text</p>｣ 
#            name => ｢p｣ 
#            child => ｢some text｣ 
#             text => ｢some text｣ 
#             textnode => ｢some text｣␤» 

Prior to the 6.d version, you could use $() shortcut to get the ast value from $/ Match if that value is truthy, or the stringification of the Match object otherwise.

'test' ~~ /.../;
# 6.c language only: 
say $(); # OUTPUT: «tes␤»; 
$/.make: 'McTesty';
say $(); # OUTPUT: «McTesty␤»;

This (non-)feature has been deprecated as of version 6.d.

Positional attributes§

$/ can have positional attributes if the Regex had capture-groups in it, which are just formed with parentheses.

'abbbbbcdddddeffg' ~~ / a (b+) c (d+ef+) g /;
say $/[0]; # OUTPUT: «｢bbbbb｣␤» 
say $/[1]; # OUTPUT: «｢dddddeff｣␤»

These can also be accessed by the shortcuts $0, $1, $2, etc.

say $0; # OUTPUT: «｢bbbbb｣␤» 
say $1; # OUTPUT: «｢dddddeff｣␤»

To get all of the positional attributes, you can use $/.list or @$/. Before 6.d, you can also use the @() shortcut (no spaces inside the parentheses).

say @$/.join; # OUTPUT: «bbbbbdddddeff␤» 
 
# 6.c language only: 
say @().join; # OUTPUT: «bbbbbdddddeff␤»

This magic behavior of @() has been deprecated as of 6.d

Named attributes§

$/ can have named attributes if the Regex had named capture-groups in it, or if the Regex called out to another Regex.

'I... see?' ~~ / \w+ $<punctuation>=[ <-[\w\s]>+ ] \s* $<final-word> = [ \w+ . ] /;
say $/<punctuation>; # OUTPUT: «｢....｣␤» 
say $/<final-word>;  # OUTPUT: «｢see?｣␤»